The R Project SVN – R – Diff – /trunk/src/scripts/check.in


#! @PERL@
#-*- perl -*-
 
## Copyright (C) 2000-2006 R Development Core Team
##
## This program is free software; you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation; either version 2, or (at your option)
## any later version.
##
## This program is distributed in the hope that it will be useful, but
## WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.	 See the GNU
## General Public License for more details.
##
## A copy of the GNU General Public License is available via WWW at
## http://www.gnu.org/copyleft/gpl.html.  You can also obtain it by
## writing to the Free Software Foundation, Inc., 51 Franklin Street,
## Fifth Floor, Boston, MA 02110-1301  USA.
 
## Send any bug reports to r-bugs@r-project.org
 
use Cwd;
use File::Basename;
use File::Copy;
use File::Find;
use File::Path;
use Getopt::Long;
use IO::File;
use R::Dcf;
use R::Logfile;
use R::Rdtools;
use R::Utils;
use R::Vars;
use Text::Wrap;
 
## Don't buffer output.
$| = 1;
 
my $revision = ' $Rev: 37725 $ ';
my $version;
my $name;
$revision =~ / ([\d\.]*) /;
$version = $1;
($name = $0) =~ s|.*/||;
 
### Options
my $opt_clean = 1;
my $opt_examples = 1;
my $opt_tests = 1;
my $opt_latex = 1;
my $opt_use_gct = 0;
my $opt_codoc = 1;
my $opt_install = 1;
my $opt_vignettes = 1;
my $opt_use_valgrind = 0;
my $opt_rcfile = "";		# Only set this if $ENV{"HOME"} is set.
$opt_rcfile = &file_path($ENV{"HOME"}, ".R", "check.conf")
    if defined($ENV{"HOME"});
my $opt_subdirs;
 
my $WINDOWS = ($R::Vars::OSTYPE eq "windows");
 
R::Vars::error("R_HOME", "R_EXE");
 
my @known_options = ("help|h", "version|v", "outdir|o:s", "library|l:s",
		     "no-clean", "no-examples", "no-tests", "no-latex",
		     "use-gct" => \$opt_use_gct, "no-codoc",
		     "install=s" => \$opt_install, "no-install",
		     "no-vignettes", "use-valgrind" => \$opt_use_valgrind,
		     "rcfile=s" => \$opt_rcfile,
		     "check-subdirs=s" => \$opt_subdirs);
GetOptions(@known_options) or usage();
 
R_version("R add-on package checker", $version) if $opt_version;
usage() if $opt_help;
 
$opt_clean = 0 if $opt_no_clean;
$opt_examples = 0 if $opt_no_examples;
$opt_tests = 0 if $opt_no_tests;
$opt_latex = 0 if $opt_no_latex;
$opt_codoc = 0 if $opt_no_codoc;
$opt_install = 0 if $opt_no_install;
$opt_vignettes = 0 if $opt_no_vignettes;
 
if($opt_install eq "fake") {
    ## If we fake installation, then we cannot *run* any code.
    $opt_examples = $opt_tests = $opt_vignettes = 0;
}
$opt_install = 0 if($opt_install eq "no");
 
my $opt_ff_calls = 1;
## The neverending story ...
## For the time being, allow to turn this off by setting the environment
## variable _R_CHECK_FF_CALLS_ to a Perl 'null' value.
if(defined($ENV{"_R_CHECK_FF_CALLS_"})) {
    $opt_ff_calls = $ENV{"_R_CHECK_FF_CALLS_"};
}
 
## Use system default unless explicitly specified otherwise.
$ENV{"R_DEFAULT_PACKAGES"} = "";
 
### Configurable variables
my $R_check_use_install_log =
    &R_getenv("_R_CHECK_USE_INSTALL_LOG_", "TRUE");
my $R_check_subdirs_nocase =
    &R_getenv("_R_CHECK_SUBDIRS_NOCASE_", "FALSE");
my $R_check_all_non_ISO_C =
    &R_getenv("_R_CHECK_ALL_NON_ISO_C_", "FALSE");
my $R_check_weave_vignettes =
    &R_getenv("_R_CHECK_WEAVE_VIGNETTES_", "TRUE");
my $R_check_subdirs_strict =
    &R_getenv("_R_CHECK_SUBDIRS_STRICT_", "default");
 
## Maybe move basic configuration (and documentation) to
##   &file_path($R::Vars::R_HOME, "etc", "check.conf")
## eventually ...
for my $file ($opt_rcfile) {
    if(-r $file) {
	open(FILE, "< $file")
	    or die "Error: cannot open file '$file' for reading\n";
	my @lines = <FILE>;
	close(FILE);
	eval("@lines");
	die "Error: failed to eval config file '$file'\n$@\n" if ($@);
	## <NOTE>
	## We prefer the above to the usual recommendation
	## 	unless ($return = do($file)) {
	## 	    warn "couldn't parse $file: $@" if $@;
	## 	    warn "couldn't do $file: $!"    unless defined $return;
	## 	    warn "couldn't run $file"       unless $return;
	##  }
	## as do(FILE) cannot see lexicals in the enclosing scope.
	## </NOTE>
    }
}
 
$R_check_use_install_log =
    &config_val_to_logical($R_check_use_install_log);
$R_check_subdirs_nocase =
    &config_val_to_logical($R_check_subdirs_nocase);
$R_check_all_non_ISO_C =
    &config_val_to_logical($R_check_all_non_ISO_C);
$R_check_weave_vignettes =
    &config_val_to_logical($R_check_weave_vignettes);
 
$opt_subdirs = $R_check_subdirs_strict if $opt_subdirs eq "";
 
my $startdir = R_cwd();
$opt_outdir = $startdir unless $opt_outdir;
chdir($opt_outdir)
    or die "Error: cannot change to directory '$opt_outdir'\n";
my $outdir = R_cwd();
chdir($startdir);
 
my $R_LIBS = $ENV{'R_LIBS'};
my $library;
if($opt_library) {
    chdir($opt_library)
	or die "Error: cannot change to directory '$opt_library'\n";
    $library = R_cwd();
    $ENV{'R_LIBS'} = env_path($library, $R_LIBS);
 
    chdir($startdir);
}
 
my $tar = R_getenv("TAR", "tar");
my $gzip = R_getenv("R_GZIPCMD", "gzip");
 
my $R_opts = "--vanilla";
 
if($opt_latex) {
    my $log = new R::Logfile();
    $log->checking("for working latex");
    open(TEXFILE,
	 "> " . &file_path(${R::Vars::TMPDIR}, "Rtextest$$.tex"))
      or die "Error: cannot open file 'Rtextest$$.tex' for writing\n";
    print TEXFILE "\\documentclass\{article\}\\begin\{document\}" .
	"test\\end\{document\}\n";
    close(TEXFILE);
    chdir($R::Vars::TMPDIR);
    if(R_system("${R::Vars::LATEX} Rtextest$$ > Rtextest$$.out")) {
	$log->result("NO");
	$HAVE_LATEX = 0;
    } else {
	$log->result("OK");
	$HAVE_LATEX = 1;
    }
    unlink(<Rtextest$$.*>);
    chdir($startdir);
    $log->close();
}
 
## This is the main loop over all packages to be checked.
(scalar(@ARGV) > 0) or die "Error: no packages were specified\n";
foreach my $pkg (@ARGV) {
    ## $pkg should be the path to the package (bundle) root source
    ## directory, either absolute or relative to $startdir.
    ## As from 2.1.0 it can also be a tarball
 
    ## $pkgdir is the corresponding absolute path.
    ## $pkgname is the name of the package (bundle).
    chdir($startdir);
    $pkg =~ s+/$++;  # strip any trailing '/'
    my $pkgname = basename($pkg);
 
    my $thispkg_subdirs = $opt_subdirs;
    ## is this a tar archive?
    my $istar = 0;
    if($pkgname =~ /\.tar\.gz$/ || $pkgname =~ /\.tgz$/) {
	$pkgname =~ s/\.tar\.gz$//;
	$pkgname =~ s/\.tgz$//;
	$pkgname =~ s/_[0-9\.-]*$//;
	$istar = 1;
	$thispkg_subdirs = "yes-maybe" if $thispkg_subdirs eq "default";
    } else {
	$thispkg_subdirs = "no" if $thispkg_subdirs eq "default";
    }
 
    my $pkgoutdir = &file_path($outdir, "$pkgname.Rcheck");
    rmtree($pkgoutdir) if ($opt_clean && (-d $pkgoutdir)) ;
    if(!(-d $pkgoutdir)) {
	mkdir($pkgoutdir, 0755)
	  or die("Error: cannot create directory '$pkgoutdir'\n");
    }
 
    if($istar) {
	my $dir = &file_path("$pkgoutdir", "00_pkg_src");
	mkdir($dir, 0755)
	  or die("Error: cannot create directory '$dir'\n");
	if($WINDOWS) {
	    ## workaround for paths in Cygwin tar
	    $pkg =~ s+^([A-Za-z]):+/cygdrive/\1+;
	}
	## this requires GNU tar: ATT 'tar x' does not support -C.
	if(R_system("$gzip -dc '$pkg' | $tar -xf - -C $dir")) {
	    die "Error: cannot untar $pkg\n";}
	$pkg = &file_path($dir, $pkgname);
    }
 
    $pkg =~ s/\/$//;
    (-d $pkg) or die "Error: package dir '$pkg' does not exist\n";
    chdir($pkg)
	or die "Error: cannot change to directory '$pkg'\n";
    my $pkgdir = R_cwd();
    ## my $pkgname = basename($pkgdir);
    my $thispkg_src_subdir = $thispkg_subdirs;
    if($thispkg_src_subdir eq "yes-maybe") {
	## now see if there is a 'configure' file
	## configure files are only used if executable, but
	## -x is always false on Windows.
	if($WINDOWS) {
	    $thispkg_src_subdir = "no" if (-f "configure");
	} else {
	    $thispkg_src_subdir = "no" if (-x "configure");
	}
    }
    chdir($startdir);
 
    $log = new R::Logfile(&file_path($pkgoutdir, "00check.log"));
    $log->message("using log directory '$pkgoutdir'");
    my @out = R_runR("cat(R.version.string, '\n', sep='')",
		     "--slave --vanilla");
    $log->message("using @out");
 
    if(!$opt_library) {
	$library = $pkgoutdir;
	$ENV{'R_LIBS'} = env_path($library, $R_LIBS);
    }
    if($WINDOWS) { ## need to avoid spaces in $library
	$library = Win32::GetShortPathName($library) if $library =~ / /;
    }
 
    my $description;
    my $is_base_pkg = 0;
    my $is_bundle = 0;
    my $package_or_bundle = "package";
    my $package_or_bundle_name;
    ## Package sources from the R distribution are special.  They have a
    ## 'DESCRIPTION.in' file (instead of 'DESCRIPTION'), with Version
    ## field containing '@VERSION@' for substitution by configure.  We
    ## test for such packages by looking for 'DESCRIPTION.in' with
    ## Priority 'base', and skip the installation test for such
    ## packages.
    if(-r &file_path($pkgdir, "DESCRIPTION.in")) {
	$description =
	  new R::Dcf(&file_path($pkgdir, "DESCRIPTION.in"));
	if($description->{"Priority"} eq "base") {
	    $log->message("looks like '${pkgname}' is a base package");
	    $log->message("skipping installation test");
	    $is_base_pkg = 1;
	}
    }
 
    if(!$is_base_pkg) {
	$log->checking(join("",
			    ("for file '",
			     &file_path($pkgname, "DESCRIPTION"),
			     "'")));
	if(-r &file_path($pkgdir, "DESCRIPTION")) {
	    $description =
	      new R::Dcf(&file_path($pkgdir, "DESCRIPTION"));
	    $log->result("OK");
	}
	else {
	    $log->result("NO");
	    exit(1);
	}
	if($description->{"Type"}) { # standard packages do not have this
	    $log->checking("extension type");
	    $log->result($description->{"Type"});
	    if($description->{"Type"} ne "Package") {
		$log->print("Only Type = Package extensions can be checked.\n");
		exit(0);
	    }
	}
 
	if($description->{"Bundle"}) {
	    $is_bundle = 1;
	    $log->message("looks like '${pkgname}' is a package bundle");
	    $package_or_bundle = "bundle";
	    $package_or_bundle_name = $description->{"Bundle"};
	}
	else {
	    $package_or_bundle_name = $description->{"Package"};
	}
	$log->message("this is $package_or_bundle " .
		      "'$package_or_bundle_name' " .
		      "version '$description->{\"Version\"}'");
 
	## Check package dependencies.
 
	## <NOTE>
	## We want to check for dependencies early, since missing
	## dependencies may make installation fail, and in any case we
	## give up if they are missing.  But we don't check them if
	## we are not going to install and hence not run any code.
	## </NOTE>
 
	if($opt_install) { 
	    ## Try figuring out whether the package dependencies can be 
	    ## resolved at run time.  
	    ## Ideally, the installation mechanism would do this,
	    ## and we also do not check versions ... also see whether vignette
	    ## and namespace package dependencies are recorded in DESCRIPTION.
	    
	    ## <NOTE>
	    ## We are not checking base packages here, so all packages do 
	    ## have a description file.  Bundles should have dependencies 
	    ## only at the top level to be usable by install.packages and 
	    ## friends, and `Writing R Extensions' requires this.
	    ## </NOTE>
 
	    $log->checking("package dependencies");
	    ## Everything listed in Depends or Suggests or Imports
	    ## should be available for successfully running R CMD check.
	    ## \VignetteDepends{} entries not "required" by the package code
	    ## must be in Suggests.  Note also that some of us think that a
	    ## package vignette must require its own package, which OTOH is
	    ## not required in the package DESCRIPTION file.
	    ## Namespace imports must really be in Depends.
	    my $Rcmd = "tools:::.check_package_depends(\"${pkgdir}\")\n";
	    my @out = R_runR($Rcmd, "${R_opts} --quiet",
			     "R_DEFAULT_PACKAGES=NULL");
	    @out = grep(!/^\>/, @out);
	    if(scalar(@out) > 0) {
		$log->error();
		$log->print(join("\n", @out) . "\n");
		$log->print(wrap("", "", @msg_DESCRIPTION));
		exit(1);
	    } else {
		$log->result("OK");
	    }
	}
 
	## <NOTE>
	## This check should be adequate, but would not catch a manually
	## installed package, nor one installed prior to 1.4.0.
	## </NOTE>
	$log->checking("if this is a source $package_or_bundle");
	if(defined($description->{"Built"})) {
	    $log->error();
	    $log->print("Only *source* packages can be checked.\n");
	    exit(1);
	}
	elsif($opt_install !~ /^check/) {
	    ## Check for package/bundle 'src' subdirectories with object
	    ## files (but not if installation was already performed).
	    my $any;
	    my $pat = "(a|o|[ls][ao]|sl|obj)"; # Object file extensions.
	    my @dirs;
	    if($is_bundle) {
		foreach my $ppkg (split(/\s+/,
					$description->{"Contains"})) {
		    push(@dirs, &file_path($ppkg, "src"));
		}
	    }
	    else {
		@dirs = ("src");
	    }
	    foreach my $dir (@dirs) {
		if((-d &file_path($pkgdir, $dir))
		   && &list_files_with_exts(&file_path($pkgdir, $dir),
					    $pat)) {
		    $log->warning() unless $any;
		    $any++;
		    $dir = &file_path($pkgname, $dir);
		    $log->print("Subdirectory '$dir' " .
				"contains object files.\n");
		}
	    }
 
	    if($thispkg_src_subdir ne "no") {
		foreach my $dir (@dirs) {
		    if((-d &file_path($pkgdir, $dir))) {
			chdir(&file_path($pkgdir, $dir));
			if(!(-f "Makefile") && !(-f "Makefile.win")) {
			    opendir(DIR, ".") or die "cannot opendir $dir: $!";
			    @srcfiles = grep { 
				!(/\.([Ccfh]|cc|cpp|f90|f95)$/
				  || /^Makevars/ || /-win\.def$/ )
				    && -f "$_" } readdir(DIR);
			    closedir(DIR);
			    if(@srcfiles) {
				$log->warning() unless $any;
				$any++;
				$log->print("Subdirectory '$dir' contains:\n");
				$log->print(wrap("  ", "  ",
						 join(" ", sort @srcfiles) . "\n"));
				$log->print(wrap("", "",
						 ("These are unlikely file names",
						  "for src files.\n")));
			    }
			}
			chdir($startdir);
		    }
		}
	    }
	    $log->result("OK") unless $any;
	}
	else {
	    $log->result("OK");
	}
 
	## Option '--no-install' turns off installation and the tests
	## which require the package to be installed.  When testing
	## recommended packages bundled with R we can skip installation,
	## and do so if '--install=skip' was given.  If command line
	## option '--install' is of the form 'check:FILE', it is assumed
	## that installation was already performed with stdout/stderr to
	## FILE, the contents of which need to be checked (without
	## repeating the installation).
	## <NOTE>
	## In this case, one also needs to specify *where* the package
	## was installed to using command line option '--library'.
	## Perhaps we should check for that, although '--install=check'
	## is really only meant for repository maintainers.
	## </NOTE>
	if($opt_install) {
	    if($opt_install eq "skip") {
		$log->message("skipping installation test");
	    }
	    else {
		my $use_install_log =
		    (($opt_install =~ /^check/) ||
		     $R_check_use_install_log ||
		     !(-t STDIN && -t STDOUT));
		my $INSTALL_opts = "";
		$INSTALL_opts = "--fake" if($opt_install eq "fake");
		my $cmd;
		if($WINDOWS) {
		    $cmd = join(" ",
				("Rcmd.exe INSTALL -l",
				 &shell_quote_file_path($library),
				 "$INSTALL_opts",
				 &shell_quote_file_path($pkgdir)));
		} else {
		    $cmd = join(" ",
				(&shell_quote_file_path(${R::Vars::R_EXE}),
				 "CMD INSTALL -l",
				 &shell_quote_file_path($library),
				 "$INSTALL_opts",
				 &shell_quote_file_path($pkgdir)));
		}
		if(!$use_install_log) {
		    ## Case A: No redirection of stdout/stderr from
		    ## installation.
		    print("\n");
		    if(R_system($cmd)) {
			$log->error();
			$log->print("Installation failed.\n");
			exit(1);
		    }
		    print("\n");
		}
		else {
		    ## Case B. All output from installation redirected,
		    ## or already available in the log file.
		    $log->checking("whether $package_or_bundle " .
				   "'$package_or_bundle_name' " .
				   "can be installed");
		    my $out = &file_path($pkgoutdir, "00install.out");
		    my $install_error;
		    my @lines;
		    if($opt_install =~ /^check/) {
			copy(substr($opt_install, 6), $out);
			$opt_install = "check";
			@lines = &read_lines($out);
			## <NOTE>
			## We used to have
			## $install_error =
			##    ($lines[$#lines] !~ /^\* DONE/);
			## but what if there is output from do_cleanup
			## in (Unix) R CMD INSTALL?
			$install_error =
			    (scalar(grep(/^\* DONE/, @lines)) == 0);
		    }
		    else {
			$cmd .= " >" .
			    &shell_quote_file_path($out) .
			    " 2>&1";
			$install_error = &R_system($cmd);
			if($WINDOWS) {
			    ## MS Html Help Compiler gives lines terminated
			    ## by CRCRLF, so we clean up the log file.
			    my $line;
			    ## read_lines does chomp.
			    @lines = &read_lines($out);
			    open(FILE, "> $out")
				or die "Error: cannot open file '$out' for re-writing\n";
			    foreach $line (@lines) {
				$line =~ s/\r$//;
				print FILE $line, "\n";
			    }
			    close(FILE);
			}
		    }
		    if($install_error) {
			$log->error();
			$log->print("Installation failed.\n");
			$log->print("See '$out' for details.\n");
			exit(1);
		    }
		    ## There could still be some important warnings that
		    ## we'd like to report.  For the time being, start
		    ## with compiler warnings about non ISO C code (Or
		    ## at least, what looks like it.)  In theory, we
		    ## should only do this when using GCC ...
		    @lines = &read_lines($out)
			unless($opt_install eq "check");
		    my $warn_re =
			"(" . join("|", ("^WARNING:",
					 "^Warning:",
					 ": warning: .*ISO C",
					 "missing link\\(s\\):")) . ")";
		    @lines = grep(/$warn_re/, @lines);
 
		    ## Ignore install time readLines() warnings about
		    ## files with incomplete final lines.  Most of these
		    ## come from .install_package_indices(), and should be
		    ## safe to ignore ...
		    $warn_re = "Warning: incomplete final line " .
			"found by readLines";
		    @lines = grep(!/$warn_re/, @lines);
 
		    ## Package writers cannot really do anything about
		    ## non ISO C code in *system* headers.  Also, GCC
		    ## 3.4 or better warns about function pointers
		    ## casts which are "needed" for dlsym(), but it
		    ## seems that all systems which have dlsym() also
		    ## support the cast.  Hence, try to ignore these by
		    ## default, but make it possible to get all ISO C
		    ## warnings via an environment variable.
		    if(!$R_check_all_non_ISO_C) {
			@lines = grep(!/^ *\/.*: warning: .*ISO C/,
				      @lines);
			$warn_re = "warning: *ISO C forbids.*" .
			    "function pointer";
			@lines = grep(!/$warn_re/, @lines);
		    }
 
		    ## Warnings spotted by gfortran 4.0 or better with
		    ## -Wall.  Justified in principle, it seems.  Let's
		    ## filter them for the time being, and maybe revert
		    ## this lateron ... but make it possible to suppress
		    ## filtering out by setting the internal environment
		    ## variable _R_CHECK_WALL_FORTRAN_ to something
		    ## "true".
		    my $R_check_Wall_FORTRAN =
			&R_getenv("_R_CHECK_WALL_FORTRAN_", "FALSE");
		    $R_check_Wall_FORTRAN =
			&config_val_to_logical($R_check_Wall_FORTRAN);
		    if(!$R_check_Wall_FORTRAN) {
			my $warn_re =
			    "(" .
			    join("|",
				 ("Label .* at \\(1\\) defined but not used",
				  "Line truncated at \\(1\\)",
				  "ASSIGN statement at \\(1\\)",
				  "Assigned GOTO statement at \\(1\\)",
				  "arithmetic IF statement at \\(1\\)")) .
			    ")";
			@lines = grep(!/$warn_re/, @lines);
		    }
 
		    if(scalar(@lines) > 0) {
			$log->warning();
			$log->print("Found the following " .
				    "significant warnings:\n");
			$log->print("  " . join("\n  ", @lines) . "\n");
		    }
		    else {
			$log->result("OK");
		    }
		}
	    }
	}
 
    }
 
    if($is_bundle) {
	my @bundlepkgs = split(/\s+/, $description->{"Contains"});
	foreach my $ppkg (@bundlepkgs) {
	    $log->message("checking '$ppkg' in bundle '$pkgname'");
	    $log->setstars("**");
	    chdir($startdir);
	    check_pkg(&file_path($pkgdir, $ppkg), $pkgoutdir, $startdir,
		      $library, $is_bundle, $description, $log,
		      $is_base_pkg);
	    $log->setstars("*");
	}
    }
    else {
	chdir($startdir);
	check_pkg($pkgdir, $pkgoutdir, $startdir, $library,
		  $is_bundle, $description, $log, $is_base_pkg, 
		  $thispkg_subdirs);
    }
 
    if($log->{"warnings"}) {
	print("\n") ;
	$log->summary();
    }
    $log->close();
    print("\n");
}
 

sub check_pkg {
 
    my ($pkg, $pkgoutdir, $startdir, $library,
	$in_bundle, $description, $log, $is_base_pkg, $subdirs) = @_;
    my ($pkgdir, $pkgname);
 
    ## $pkg is the argument we received from the main loop.
    ## $pkgdir is the corresponding absolute path,
    ## $pkgname the name of the package.
    ## Note that we need to repeat the checking from the main loop in
    ## the case of package bundles (and we could check for this).
 
    $log->checking("package directory");
    chdir($startdir);
    $pkg =~ s/\/$//;
    if(-d $pkg) {
	chdir($pkg)
	  or die "Error: cannot change to directory '$pkg'\n";
	$pkgdir = R_cwd();
	if($in_bundle) {
	    $pkgname = basename($pkgdir);
	} else {
	    $pkgname = $description->{"Package"};
	}
    }
    else {
	$log->error();
	$log->print("Package directory '$pkg' does not exist.\n");
	exit(1);
    }
    $log->result("OK");
 
    chdir($pkgdir);
 
    ## Build list of exclude patterns.
 
    my @exclude_patterns = R::Utils::get_exclude_patterns();
    my $exclude_file = ".Rbuildignore";
    ## This is a bit tricky for bundles where the build ignore pattern
    ## file is in the top-level bundle dir.
    $exclude_file = &file_path(dirname($pkgdir), $exclude_file);
    if(-f $exclude_file) {
	open(RBUILDIGNORE, "< $exclude_file");
	while(<RBUILDIGNORE>) {
	    chop;
	    push(@exclude_patterns, $_) if $_;
	}
	close(RBUILDIGNORE);
    }
 
    ## Check for portable file names.
 
    ## Ensure that the names of the files in the package are valid for
    ## at least the supported OS types.  Under Unix, we definitely
    ## cannot have '/'; under Windows, the control characters as well as
    ##   " * : < > ? \ |
    ## (i.e., ASCII characters 1 to 31 and 34, 36, 58, 60, 62, 63, 92,
    ## and 124) are or can be invalid.  (In addition, one cannot have
    ## one-character file names consisting of just ' ', '.', or '~'.)
    ## Based on information by Uwe Ligges, Duncan Murdoch, and Brian
    ## Ripley.
 
    ## Furthermore, Uwe Ligges says that Windows still does not allow
    ## the following DOS device names (by themselves or with possible
    ## extensions):
    ##
    ## Name    Function
    ## ----    --------
    ## CON     Keyboard and display
    ## PRN     System list device, usually a parallel port
    ## AUX     Auxiliary device, usually a serial port
    ## CLOCK$  System real-time clock
    ## NUL     Bit-bucket device
    ## COM1    First serial communications port
    ## COM2    Second serial communications port
    ## COM3    Third serial communications port
    ## COM4    Fourth serial communications port
    ## LPT1    First parallel printer port
    ## LPT2    Second parallel printer port
    ## LPT3    Third parallel printer port
 
    ## In addition, the names of help files get converted to HTML
    ## file names and so should be valid in URLs.  We check that they are
    ## ASCII and do not contain %, which is what is known to cause troubles.
 
    $log->checking("for portable file names");
    my @bad_files = ();
    sub find_wrong_names {
	my $file_path = $File::Find::name;
	$file_path =~ s/^\.[^\/]*\///;
	foreach my $p (@exclude_patterns) {
	    if($WINDOWS) {
		## Argh: Windows is case-honoring but not
		## case-insensitive ...
		return 0 if($file_path =~ /$p/i);
	    }
	    else {
		return 0 if($file_path =~ /$p/);
	    }
	}
	my $file_name = basename($file_path);
	if(grep(/[[:cntrl:]\"\*\/\:\<\>\?\\\|]/, $file_name)) {
	    push(@bad_files, $file_path);
	} elsif(dirname($file_path) =~ /man$/) {
	    my $ch;
	    foreach $ch (split //, $file_name) {
		## collation is ASCII as uselocale is not in effect.
		if ($ch eq "%" || $ch lt " " || $ch gt "~")  {
		    push(@bad_files, $file_path);
		    last;
		}
	    }
	} else {
	    $file_name =~ tr/A-Z/a-z/;
	    $file_name =~ s/\..*//;
	    push(@bad_files, $file_path)
	      if(grep(/^(con|prn|aux|clock\$|nul|lpt[1-3]|com[1-4])$/,
		     $file_name));
	}
    }
    if($in_bundle) {
	chdir(dirname($pkgdir)); # more portable than '..'?
	find(\&find_wrong_names, $pkgname);
	chdir($pkgname);
    }
    else {
	find(\&find_wrong_names, ".");
    }
    if(scalar(@bad_files) > 0) {
	$log->error();
	$log->print("Found the following file(s) with " .
		    "non-portable file names:\n");
	$log->print("  " . join("\n  ", @bad_files) . "\n");
	$log->print(wrap("", "",
			 ("These are not valid file names",
			  "on all R platforms.\n",
			  "Please rename the files and try again.\n",
			  "See section 'Package structure'",
			  "in manual 'Writing R Extensions'.\n")));
	exit(1);
    }
 
    ## next check for name clashes on case-insensitive file systems
    ## (that is on Windows).
    %seen = ();
    my @duplicated = ();
    sub check_case_names {
	my $file_path = lc($File::Find::name);
	if($seen{$file_path}) {push(@duplicated, $file_path);}
	$seen{$file_path}  = 1;
    }
    if($in_bundle) {
	chdir(dirname($pkgdir)); # more portable than '..'?
	find(\&check_case_names, $pkgname);
	chdir($pkgname);
    }
    else {
	find(\&check_case_names, ".");
    }
    if(scalar(@duplicated) > 0) {
	$log->error();
	$log->print("Found the following file(s) with " .
		    "duplicate lower-cased file names:\n");
	$log->print("  " . join("\n  ", @duplicated) . "\n");
	$log->print(wrap("", "",
			 ("File names must not differ just by case",
			  "to be usable on all R platforms.\n",
			  "Please rename the files and try again.\n",
			  "See section 'Package structure'",
			  "in manual 'Writing R Extensions'.\n")));
	exit(1);
    }
 
    $log->result("OK");
 
    ## Check for sufficient file permissions (Unix only).
 
    ## This used to be much more 'aggressive', requiring that dirs and
    ## files have mode >= 00755 and 00644, respectively (with an error
    ## if not), and that files know to be 'text' have mode 00644 (with a
    ## warning if not).  We now only require that dirs and files have
    ## mode >= 00700 and 00400, respectively, and try to fix
    ## insufficient permission in the INSTALL code (Unix only).
    ##
    ## In addition, we check whether files 'configure' and 'cleanup'
    ## exists in the top-level directory but are not executable, which
    ## is most likely not what was intended.
 
    if($R::Vars::OSTYPE eq "unix") {
	$log->checking("for sufficient/correct file permissions");
	my @bad_files = ();
 
	## Phase A.  Directories at least 700, files at least 400.
	sub find_wrong_perms_A {
	    my $filename = $File::Find::name;
	    $filename =~ s/^\.[^\/]*\///;
	    foreach my $p (@exclude_patterns) {
		## Unix only, so no special casing for Windows.
		return 0 if($filename =~ /$p/);
	    }
	    if(-d $_ && (((stat $_)[2] & 00700) < oct("700"))) {
		push(@bad_files, $filename);
	    }
	    if(-f $_ && (((stat $_)[2] & 00400) < oct("400"))) {
		push(@bad_files, $filename);
	    }
	}
	if($in_bundle) {
	    chdir(dirname($pkgdir)); # more portable than '..'?
	    find(\&find_wrong_perms_A, $pkgname);
	    chdir($pkgname);
	}
	else {
	    find(\&find_wrong_perms_A, ".");
	}
        if(scalar(@bad_files) > 0) {
	    $log->error();
	    $log->print("Found the following files with " .
			"insufficient permissions:\n");
	    $log->print("  " . join("\n  ", @bad_files) . "\n");
	    $log->print(wrap("", "",
			     ("Permissions should be at least 700",
			      "for directories and 400 for files.\n",
			      "Please fix permissions",
			      "and try again.\n")));
	    exit(1);
	}
 
	## Phase B.  Top-level scripts 'configure' and 'cleanup' should
	## really be mode at least 500, or they will not be necessarily
	## be used (or should we rather change *that*?)
	@bad_files = ();
	foreach my $filename ("configure", "cleanup") {
	    ## This is a bit silly ...
	    my $ignore = 0;
	    foreach my $p (@exclude_patterns) {
		if($filename =~ /$p/) {
		    $ignore = 1;
		    last;
		}
	    }
	    if(!$ignore
	       && (-f $filename)
	       && (((stat $filename)[2] & 00500) < oct("500"))) {
		push(@bad_files, $filename);
	    }
	}
	if(scalar(@bad_files) > 0) {
	    $log->warning();
	    $log->print(wrap("", "",
			     "The following files should most likely",
			     "be executable (for the owner):\n"));
	    $log->print("  " . join("\n  ", @bad_files) . "\n");
	    $log->print(wrap("", "",
			     "Please fix permissions.\n"));
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check DESCRIPTION meta-information.
 
    ## If we just installed the package (via R CMD INSTALL), we already
    ## validated most of the package DESCRIPTION metadata.  Otherwise,
    ## let us be defensive about this ...
 
    my $full =
	!$opt_install || ($opt_install eq "skip") || $is_base_pkg;
    &R::Utils::check_package_description($pkgdir, $pkgname, $log,
					 $in_bundle, $is_base_pkg,
					 $full);
 
    $log->checking("top-level files");
    opendir(DIR, ".") or die "cannot opendir package: $!";
    my @topfiles = grep { /^install.R$/ || /^R_PROFILE.R/
			      && -f "$_" } readdir(DIR);
    closedir(DIR);
    if(@topfiles) {
	$log->warning();
	    $log->print(join(" ", @topfiles) . "\n");
	    $log->print(wrap("", "",
			     ("These files are deprecated.",
			      "See manual 'Writing R Extensions'.\n")));
    } else {
	$log->result("OK");
    }
 
    ## Check index information.
 
    $log->checking("index information");
    my @msg_index = ("See the information on INDEX files and package",
		     "subdirectories in section 'Creating R packages'",
		     "of the 'Writing R Extensions' manual.\n");
    my $any = 0;
    if(-z "INDEX") {
	## If there is an empty INDEX file, we get no information about
	## the package contents ...
	$any++;
	$log->warning();
	$log->print("Empty file 'INDEX'.\n");
    }
    if((-d "demo")
       && &list_files_with_type("demo", "demo")) {
	my $index = &file_path("demo", "00Index");
	if(!(-s $index)) {
	    $log->warning() unless($any);
	    $any++;
	    $log->print("Empty or missing file '$index'.\n");
	}
	else {
	    my $dir = "demo";
	    my $Rcmd = "options(warn=1)\ntools:::.check_demo_index(\"$dir\")\n";
	    my @out = R_runR($Rcmd, "${R_opts} --quiet",
			     "R_DEFAULT_PACKAGES=NULL");
	    @out = grep(!/^\>/, @out);
	    if(scalar(@out) > 0) {
		$log->warning() unless($any);
		$any++;
		$log->print(join("\n", @out) . "\n");
	    }
	}
    }
    if((-d &file_path("inst", "doc"))
       && &list_files_with_type(&file_path("inst", "doc"),
				"vignette")) {
	my $dir = &file_path("inst", "doc");
	my $Rcmd = "options(warn=1)\ntools:::.check_vignette_index(\"$dir\")\n";
	my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES=NULL");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    $log->warning() unless($any);
	    $any++;
	    $log->print(join("\n", @out) . "\n");
	}
    }
    if($any) {
	$log->print(wrap("", "", @msg_index));
    }
    else {
	$log->result("OK");
    }
 
    ## Check package subdirectories.
 
    $log->checking("package subdirectories");
    my $any;
    if($R_check_subdirs_nocase) {
	## Argh.  We often get submissions where 'R' comes out as 'r',
	## or 'man' comes out as 'MAN'.  Maybe we should warn about this
	## unconditionally ...
	if((-d "r")) {
	    $log->warning() unless $any;
	    $any++;
	    $log->print("Found subdirectory 'r'.\n");
	    $log->print("Most likely, this should be 'R'.\n")
	}
	if((-d "MAN")) {
	    $log->warning() unless $any;
	    $any++;
	    $log->print("Found subdirectory 'MAN'.\n");
	    $log->print("Most likely, this should be 'man'.\n")
	}
    }
    sub check_subdirs {
	my ($dpath) = @_;
	my $Rcmd = "tools:::.check_package_subdirs(\"$dpath\")\n";
	my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES=NULL");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    $log->warning() unless($any);
	    $any++;
	    $log->print(join("\n", @out) . "\n");
	    $log->print(wrap("", "",
			     ("Please remove or rename the files.\n",
			      "See section 'Package subdirectories'",
			      "in manual 'Writing R Extensions'.\n")));
	}
    }
    &check_subdirs(".") unless ($subdirs eq "no");
    ## Subdirectory 'data' without data sets?
    if((-d "data") && !&list_files_with_type("data", "data")) {
	$log->warning() unless $any;
	$any++;
	$log->print("Subdirectory 'data' contains no data sets.\n");
    }
    ## Subdirectory 'demo' without demos?
    if((-d "demo") && !&list_files_with_type("demo", "demo")) {
	$log->warning() unless $any;
	$any++;
	$log->print("Subdirectory 'demo' contains no demos.\n");
    }
    ## Subdirectory 'src' without sources?
    ## <NOTE>
    ## If there is a Makefile (or a Makefile.win), we cannot assume
    ## that source files have the predefined extensions.
    ## </NOTE>
    if( (-d "src") && !( (-f &file_path("src", "Makefile"))
			 || (-f &file_path("src", "Makefile.win")) )) {
	if( !(&list_files_with_exts("src", "([Ccf]|cc|cpp|f90|f95)"))) {
	    $log->warning() unless $any;
	    $any++;
	    $log->print("Subdirectory 'src' contains no source files.\n");
	}
    }
    ## Do subdirectories of 'inst' interfere with R package system
    ## subdirectories?
    if((-d "inst")) {
	my @R_system_subdirs =
	    ("Meta", "R", "data", "demo", "exec", "libs",
	     "man", "help", "html", "latex", "R-ex");
	my @bad_dirs = ();
	foreach my $dir (@R_system_subdirs) {
	    push(@bad_dirs, $dir)
		if((-d &file_path("inst", $dir))
		   && &list_files(file_path("inst", $dir)));
	}
	if(scalar(@bad_dirs) > 0) {
	    $log->warning() unless $any;
	    $any++;
	    $log->print(wrap("", "",
			     ("Found the following non-empty",
			      "subdirectories of 'inst' also",
			      "used by R:\n")));
	    $log->print("  " . join(" ", @bad_dirs) . "\n");
	    $log->print(wrap("", "",
			     ("It is recommended not to interfere",
			      "with package subdirectories",
			      "used by R.\n")));
	}
    }
    $log->result("OK") unless $any;
 
    ## Check R code for syntax errors.
 
    if(!$is_base_pkg && (-d "R")) {
	$log->checking("R files for syntax errors");
	## <NOTE>
	## We could/should really check *all* OS specific subdirs here.
	my @R_files = &list_files_with_type("R", "code");
	## </NOTE>
	my $Rcmd = "RFiles <- c(\"";
	$Rcmd .= join("\",\n\"", @R_files) . "\")\n";
	$Rcmd .= "for(f in RFiles)\n";
	$Rcmd .= "if(inherits(try(parse(f)), \"try-error\")) stop(f)\n";
        my @out = R_runR($Rcmd, "${R_opts} --quiet");
	@out = grep(/^Error:/, @out);
	if(scalar(@out) > 0) {
	    my $Rfile = $out[0];
	    $Rfile =~ s/^Error: *//;
	    $log->error();
	    $log->print("Syntax error in file '$Rfile'\n");
	    exit(1);
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check usage of library.dynam (if any).
 
    if(!$is_base_pkg && (-d "R")) {
	$log->checking("R files for library.dynam");
	my @R_files;
	if($opt_install) {
	    ## Only need to check the installed file (if installed).
	    @R_files = (&file_path($library, $pkgname, "R", $pkgname));
	}
	else {
	    ## Otherwise (if the package was not installed), we need to
	    ## check all R code files.
	    ## <NOTE>
	    ## We could/should really check all OS specific subdirs here.
	    @R_files = &list_files_with_type("R", "code");
	    ## </NOTE>
	}
	my $any = 0;
	my $ext;
	foreach my $file (@R_files) {
	    last if $any;
	    open(FILE, "< $file")
	      or die "Error: cannot open file '$file' for reading\n";
	    while(<FILE>) {
		if(/library.dynam\(\"(.*?)\"/o) {
		    my $arg = $1;
		    if($arg =~ /\.(so|sl|dll)$/) {
			$ext = $1;
			$any++;
			last;
		    }
		}
	    }
	    close(FILE);
	}
	if($any == 0) {
	    $log->result("OK");
	}
	else {
	    $log->error();
	    $log->print("library.dynam() used with extension '.$ext'.\n");
	    $log->print(wrap("", "",
			     ("The system-specific extension for",
			      "shared libraries should not be added.\n",
			      "See ?library.dynam\n")));
	    exit(1);
	}
    }
 
    ## Check whether methods have all arguments of the corresponding
    ## generic.
 
    if(-d "R") {
	$log->checking("S3 generic/method consistency");
 
	my @msg_S3_methods =
	  ("See section 'Generic functions and methods'",
	   "of the 'Writing R Extensions' manual.\n");
 
	my $Rcmd = "options(warn=1)\n";
	$Rcmd .= "options(expressions=1000)\n";
	if($opt_install) {
	    $Rcmd .= "tools::checkS3methods(package = \"${pkgname}\")\n";
	}
        else {
	    $Rcmd .= "tools::checkS3methods(dir = \"${pkgdir}\")\n";
	}
 
        my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    $log->warning();
	    $log->print(join("\n", @out) . "\n");
	    $log->print(wrap("", "", @msg_S3_methods));
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check whether replacement functions have their final argument
    ## named 'value'.
 
    if(-d "R") {
	$log->checking("replacement functions");
 
	my @msg_replace_funs =
	  ("In R, the argument of a replacement function",
	   "which corresponds to the right hand side",
	   "must be named 'value'.\n");
 
	my $Rcmd = "options(warn=1)\n";
	if($opt_install) {
	    $Rcmd .= "tools::checkReplaceFuns(package = \"${pkgname}\")\n";
	}
	else {
	    $Rcmd .= "tools::checkReplaceFuns(dir = \"${pkgdir}\")\n";
	}
 
        my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
        @out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    ## <NOTE>
	    ## We really want to stop if we find offending replacement
	    ## functions.  But we cannot use error() because output may
	    ## contain warnings ...
	    $log->warning();
	    ## </NOTE>
	    $log->print(join("\n", @out) . "\n");
	    $log->print(wrap("", "", @msg_replace_funs));
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check foreign function calls.
 
    if($opt_ff_calls && (-d "R")) {
	$log->checking("foreign function calls");
 
	my @msg_ff_calls =
	  ("See section 'System and foreign language interfaces'",
	   "of the 'Writing R Extensions' manual.\n");
 
	my $Rcmd = "options(warn=1)\n";
	if($opt_install) {
	    $Rcmd .= "tools::checkFF(package = \"${pkgname}\")\n";
	}
        else {
	    $Rcmd .= "tools::checkFF(dir = \"${pkgdir}\")\n";
	}
 
        my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    $log->warning();
	    $log->print(join("\n", @out) . "\n");
	    $log->print(wrap("", "", @msg_ff_calls));
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check R code for possible problems using LT's codetools package
    ## available from http://www.stat.uiowa.edu/~luke/R/codetools, and
    ## scheduled for integration into base R eventually).
 
    ## Activated only via setting the internal environment variable
    ## _R_CHECK_USE_CODETOOLS_ to something "true".
 
    my $R_check_use_codetools =
	&R_getenv("_R_CHECK_USE_CODETOOLS_", "FALSE");
    $R_check_use_codetools =
	&config_val_to_logical($R_check_use_codetools);
 
    if($R_check_use_codetools && $opt_install && (-d "R")) {
	$log->checking("R code for possible problems");
 
	my $Rcmd = "options(warn=1)\n";
	$Rcmd .= "tools:::.check_code_usage_in_package(package = \"${pkgname}\")\n";
	my @out = R_runR($Rcmd, "${R_opts} --quiet",
                         "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	@out = grep(!/^\>/, @out);
 
 
 
 
 
	if(scalar(@out) > 0) {
	    $log->warning();
	    $log->print(join("\n", @out) . "\n");
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check R documentation files.
 
    my @msg_writing_Rd
      = ("See chapter 'Writing R documentation files'",
	 "in manual 'Writing R Extensions'.\n");
 
    if(-d "man") {
	$log->checking("Rd files");
 
	my $Rcmd = "options(warn=1)\ntools:::check_Rd_files_in_man_dir(\"man\")\n";
	my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES=NULL");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    ## Output may indicate warnings or errors ...
	    if(grep(/^Rd files with (syntax errors|missing or empty)/,
		    @out)) {
		$log->error();
		$log->print(join("\n", @out) . "\n");
		$log->print(wrap("", "", @msg_writing_Rd));
		exit(1);
	    }
	    else {
		$log->warning();
		$log->print(join("\n", @out) . "\n");
		$log->print(wrap("", "", @msg_writing_Rd));
	    }
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check cross-references in R documentation files.
 
    ## <NOTE>
    ## Installing a package warns about missing links (and hence R CMD
    ## check knows about this too provided an install log is used).
    ## However, under Windows the install-time check verifies the links
    ## against what is available in the default library, which might be
    ## considerably more than what can be assumed to be available.
    ##
    ## The formulations in section "Cross-references" of R-exts are not
    ## quite clear about this, but CRAN policy has for a long time
    ## enforced anchoring links to targets (aliases) from non-base
    ## packages.
    ##
    ## For the time being, if the package is installed only run the test
    ## if the internal environment variable _R_CHECK_RD_XREFS_ is set to
    ## something "true".  Most likely one should always run the check if
    ## no install log is used.
 
    if(-d "man") {
	my $R_check_Rd_xrefs = &R_getenv("_R_CHECK_RD_XREFS_", "FALSE");
	$R_check_Rd_xrefs = &config_val_to_logical($R_check_Rd_xrefs);
 
	if(($opt_install && $R_check_Rd_xrefs) || !$opt_install) {
 
	    $log->checking("Rd cross-references");
 
	    my $Rcmd = "options(warn=1)\n";
	    if($opt_install) {
		$Rcmd .= "tools:::.check_Rd_xrefs(package = \"${pkgname}\")\n";
	    }
	    else {
		$Rcmd .= "tools:::.check_Rd_xrefs(dir = \"${pkgdir}\")\n";
	    }
 
	    my @out = R_runR($Rcmd, "${R_opts} --quiet",
			     "R_DEFAULT_PACKAGES=NULL");
	    @out = grep(!/^\>/, @out);
	    if(scalar(@out) > 0) {
		$log->warning();
		$log->print(join("\n", @out) . "\n");
	    }
	    else {
		$log->result("OK");
	    }
	}
    }
 
    ## Check for missing documentation entries.
 
    if(((-d "R") || (-d "data"))) {
	$log->checking("for missing documentation entries");
 
	my $Rcmd= "options(warn=1)\n";
	if($opt_install) {
	    $Rcmd .= "tools::undoc(package = \"${pkgname}\")\n";
	}
	else {
	    $Rcmd .= "tools::undoc(dir = \"${pkgdir}\")\n";
	}
 
        my @out = R_runR($Rcmd, "${R_opts} --quiet",
                         "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	my @err = grep(/^Error/, @out);
	@out = grep(!/^\>/, @out);
	if(scalar(@err) > 0) {
	    $log->error();
	    $log->print(join("\n", @err) . "\n");
	    exit(1);
	}
	elsif(scalar(@out) > 0) {
	    $log->warning();
	    $log->print(join("\n", @out) . "\n");
	    my $details;
	    $details = " (including S4 classes and methods)"
	      if(grep(/^Undocumented S4/, @out));
	    $log->print(wrap("", "",
			     ("All user-level objects",
			      "in a package${details} should",
			      "have documentation entries.\n")));
	    $log->print(wrap("", "", @msg_writing_Rd));
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check for code/documentation mismatches.
 
    if($opt_codoc && (-d "man")) {
	$log->checking("for code/documentation mismatches");
 
	my $any = 0;
 
	## Check for code/documentation mismatches in functions.
	if(-d "R") {
	    my $Rcmd = "options(warn=1)\n";
	    if($opt_install) {
		$Rcmd .= "tools::codoc(package = \"${pkgname}\")\n";
	    }
	    else {
		$Rcmd .= "tools::codoc(dir = \"${pkgdir}\")\n";
	    }
	    my @out = R_runR($Rcmd, "${R_opts} --quiet",
			     "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
 
	    @out = grep(!/^\>/, @out);
	    if(scalar(@out) > 0) {
		$any++;
		$log->warning();
		$log->print(join("\n", @out) . "\n");
	    }
	}
 
	## Check for code/documentation mismatches in data sets.
	if($opt_install) {
	    my $Rcmd = "options(warn=1)\ntools::codocData(package = \"${pkgname}\")\n";
	    my @out = R_runR($Rcmd, "${R_opts} --quiet",
			     "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	    @out = grep(!/^\>/, @out);
	    if(scalar(@out) > 0) {
		$log->warning() unless($any);
		$any++;
		$log->print(join("\n", @out) . "\n");
	    }
	}
 
	## Check for code/documentation mismatches in S4 classes.
	if($opt_install && (-d "R")) {
	    my $Rcmd = "options(warn=1)\ntools::codocClasses(package = \"${pkgname}\")\n";
	    my @out = R_runR($Rcmd, "${R_opts} --quiet",
			     "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	    @out = grep(!/^\>/, @out);
	    if(scalar(@out) > 0) {
		$log->warning() unless($any);
		$any++;
		$log->print(join("\n", @out) . "\n");
	    }
	}
 
	$log->result("OK") unless($any);
 
    }
 
    ## Check Rd files, for consistency of \usage with \arguments (are
    ## all arguments shown in \usage documented in \arguments?) and
    ## aliases (do all functions shown in \usage have an alias?)
 
    if(-d "man") {
	$log->checking("Rd \\usage sections");
 
	my @msg_doc_files =
	  ("Functions with \\usage entries",
	   "need to have the appropriate \\alias entries,",
	   "and all their arguments documented.\n",
	   "The \\usage entries must correspond to syntactically",
	   "valid R code.\n");
 
	my $Rcmd = "options(warn=1)\n";
	if($opt_install) {
	    $Rcmd .= "tools::checkDocFiles(package = \"${pkgname}\")\n";
	}
	else {
	    $Rcmd .= "tools::checkDocFiles(dir = \"${pkgdir}\")\n";
	}
 
        my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES='utils,grDevices,graphics,stats'");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    $log->warning();
	    $log->print(join("\n", @out) . "\n");
	    $log->print(wrap("", "", @msg_doc_files));
	    $log->print(wrap("", "", @msg_writing_Rd));
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check C/C++/Fortran sources/headers for CRLF line endings.
 
    ## <FIXME>
    ## Does ISO C really require LF line endings?  (Reference?)
    ## We definitely know that some versions of Solaris cc and f77
    ## will not accept CRLF or CR line endings.
    ## Note that we currently only check the CRLF part.
    ## </FIXME>
 
    if(!$is_base_pkg && (-d "src")) {
	$log->checking("for CRLF line endings in C/C++/Fortran sources/headers");
	my @src_files = &list_files_with_exts("src", "(c|h|f|cc|cpp)");
	my @bad_files = ();
	foreach my $file (@src_files) {
	    open(FILE, "< $file")
	      or die "Error: cannot open '$file' for reading\n";
            binmode(FILE);	# for Windows
	    while(<FILE>) {
		chop;
		if($_ =~ /\r$/) {
		    push(@bad_files, $file);
		    last;
		}
	    }
	    close(FILE);
	}
	if(scalar(@bad_files) > 0) {
	    $log->warning();
	    $log->print("Found the following sources/headers with " .
			"CRLF line endings:\n");
	    $log->print("  " . join("\n  ", @bad_files) . "\n");
	    $log->print("Some Unix compilers require LF line endings.\n");
	}
	else {
	    $log->result("OK");
	}
    }
 
    ## Check src/Makevars[.in] for portable compilation flags.
 
    if((-f &file_path("src", "Makevars.in"))
       || (-f &file_path("src", "Makevars"))) {
	$log->checking("for portable compilation flags in Makevars");
	my $Rcmd = "tools:::.check_make_vars(\"src\")\n";
	my @out = R_runR($Rcmd, "${R_opts} --quiet",
			 "R_DEFAULT_PACKAGES=NULL");
	@out = grep(!/^\>/, @out);
	if(scalar(@out) > 0) {
	    $log->warning();
	    $log->print(join("\n", @out) . "\n");
	}
	else {
	    $log->result("OK");
	}
    }
 
 
    chdir($pkgoutdir);
 
    ## Run the examples.
    ## This setting applies to vignettes below too.
    ${R_opts} = ${R_opts}." -d valgrind" if $opt_use_valgrind;
 
    if($opt_examples && (-d &file_path($library, $pkgname, "R-ex"))) {
	$log->creating("${pkgname}-Ex.R");
	my $Rexdir = &file_path($library, $pkgname, "R-ex");
        ## $Rexdir might contain spaces (not on Windows)
        my $is_zipped = 0;
	my $cmd;
 
        if(-e &file_path($Rexdir, "Rex.zip")) {
            $is_zipped = 1;
	    my $UNZIP = &R_getenv("R_UNZIPCMD", "unzip");
            my $Rexfile = &file_path($Rexdir, "Rex.zip");
	    $cmd = join(" ",
			("$UNZIP", "-q",
			 &shell_quote_file_path($Rexfile),
			 "-d",
			 &shell_quote_file_path($Rexdir)));
	    if(R_system($cmd)) {
		$log->error();
		$log->print("Cannot extract examples from ZIP archive.\n");
		exit(1);
	    }
        }
        if($WINDOWS) {
            ## avoid Rcmd as line may be too long after expansion.
            ## We've forced R_HOME and Rexdir to have no spaces already.
            $cmd = "perl ${R::Vars::R_HOME}/bin/massage-Examples ".
  		     "${pkgname} ${Rexdir} ".
  		     "> ${pkgname}-Ex.R";
        } else {
	    $cmd =
		join(" ",
		     (&shell_quote_file_path(${R::Vars::R_EXE}),
		      "CMD perl",
		      &shell_quote_file_path(&file_path(${R::Vars::R_SHARE_DIR},
							"perl",
							"massage-Examples.pl")),
		      "${pkgname}",
		      &shell_quote_file_path(${Rexdir}),
		      "> ${pkgname}-Ex.R"));
        }
 
 	if(R_system($cmd)) {
  	    $log->error();
	    $log->print("Running massage-Examples to create " .
			"${pkgname}-Ex.R failed.\n");
  	    exit(1);
        }
        if($is_zipped) {
            unlink(&list_files_with_exts($Rexdir, "R"));
        }
 
	$log->result("OK");
	$log->checking("examples");
 
	if($opt_use_gct) {
            $cmd = join(" ",
			("(echo 'gctorture(TRUE)';",
			 "cat ${pkgname}-Ex.R) |",
			 &shell_quote_file_path(${R::Vars::R_EXE}),
			 "${R_opts}",
			 "> ${pkgname}-Ex.Rout 2>&1"));
	} else {
	    $cmd = join(" ",
			(&shell_quote_file_path(${R::Vars::R_EXE}),
			 "${R_opts}",
			 "< ${pkgname}-Ex.R",
			 "> ${pkgname}-Ex.Rout 2>&1"));
	}
	if(R_system($cmd)) {
	    $log->error();
	    $log->print("Running examples in ${pkgname}-Ex.R failed.\n");
	    ## Try to spot the offending example right away.
	    my $txt = join("\n", &read_lines("${pkgname}-Ex.Rout"));
	    ## Look for the header section anchored by a subsequent call
	    ## to flush(): needs to be kept in sync with the code in
	    ## massage-Examples.pl.  Should perhaps also be more
	    ## defensive about the prompt ...
	    my @chunks = split(/(> \#\#\# \* [^\n]+\n> \n> flush)/, $txt);
	    if(scalar(@chunks) > 2) {
		$log->print("The error most likely occurred in:\n\n");
		$log->print($chunks[$#chunks - 1]);
		$log->print($chunks[$#chunks] . "\n");
	    }
	    exit(1);
	}
	## Look at the output from running the examples.  For the time
	## being, report warnings about use of deprecated functions, as
	## the next release will make them defunct and hence using them
	## an error.  Also warn about loading defunct base package stubs,
	## as load special-casing for these will be removed eventually.
	my @lines = &read_lines("${pkgname}-Ex.Rout");
	my $any;
	my @bad_lines;
	@bad_lines = grep(/^Warning: .*is deprecated.$/, @lines);
	if(scalar(@bad_lines) > 0) {
	    $log->warning();
	    $any++;
	    $log->print("Found the following significant warnings:\n");
	    $log->print("  " . join("\n  ", @bad_lines) . "\n");
	    $log->print(wrap("", "",
			     ("Deprecated functions may be defunct as",
			      "soon as of the next release of R.\n",
			      "See ?Deprecated.\n")));
	}
	@bad_lines = grep(/^Warning: package '.*' has been merged into/,
			  @lines);
	## Could make this more precise by looking for an exact match
	## for one of the defunct stubs, but we currently do not get
	## R_PKGS_STUBS from 'share/make/vars.mk'.
	if(scalar(@bad_lines) > 0) {
	    if($any) {
		$log->print("\nAdditional significant warnings:\n");
	    }
	    else {
		$log->warning();
		$any++;
		$log->print("Found the following significant " .
			    "warnings:\n");
	    }
	    $log->print("  " . join("\n  ", @bad_lines) . "\n");
	    $log->print(wrap("", "",
			     ("Support for loading defunct former base",
			      "packages may be removed as soon as of",
			      "the next release of R.\n")));
	}
	$log->result("OK") unless($any);
    }
 
    ## Run the package-specific tests.
 
    if($opt_install && $opt_tests && (-d &file_path($pkgdir, "tests"))) {
        $log->checking("tests");
        my $testsrcdir = &file_path($pkgdir, "tests");
        my $testdir = &file_path($pkgoutdir, "tests");
        if(!(-d $testdir)) {
            mkdir($testdir, 0755)
	      or die "Error: cannot create directory '$testdir'\n";
        }
        chdir($testdir);
	foreach my $file (&list_files($testsrcdir)) {
	    copy($file, basename($file));
	}
        my $makefiles = "-f " .
	    &shell_quote_file_path(&file_path(${R::Vars::R_SHARE_DIR},
					      "make", "tests.mk"));
        if($WINDOWS) {
            $makefiles = "-f ${R::Vars::R_SHARE_DIR}/make/wintests.mk";}
        my $makevars = "";
        if($WINDOWS && (-r "$testsrcdir/Makefile.win")) {
            $makefiles .= " -f $testsrcdir/Makefile.win";
        }
        elsif(-r &file_path($testsrcdir, "Makefile")) {
            $makefiles .= " -f " . &file_path($testsrcdir, "Makefile");
        }
        if($WINDOWS && (-r "$testsrcdir/Makevars.win")) {
            $makevars = " -f $testsrcdir/Makevars.win";
        }
        elsif(-r &file_path($testsrcdir, "Makevars")) {
            $makevars = " -f " . &file_path($testsrcdir, "Makevars");
        }
        else {
            open(MAKEVARS, "> Makevars");
            print MAKEVARS "makevars = -f Makevars\n";
            print MAKEVARS "srcdir = $testsrcdir\n";
            ## at least windows does not pass env correctly to make
            print MAKEVARS "R_LIBS = $ENV{'R_LIBS'}\n";
            print MAKEVARS "VPATH = \$(srcdir)\n\n";
            print MAKEVARS "test-src-1 =";
	    foreach my $file (sort &list_files_with_exts($testdir, "R")) {
                print MAKEVARS "\\\n " . basename($file);
            }
            print MAKEVARS "\n";
            print MAKEVARS "test-src-auto =";
	    foreach my $file (sort &list_files_with_exts($testdir, "Rin")) {
                $file =~ s/Rin$/R/;
                print MAKEVARS "\\\n " . basename($file);
            }
            print MAKEVARS "\n";
	    print MAKEVARS "USE_GCT = $opt_use_gct\n";
	    print MAKEVARS "R_OPTS = -d valgrind\n" if $opt_use_valgrind;
            close(MAKEVARS);
            $makevars = " -f Makevars";
        }
        print "\n";
        if(R_system("${R::Vars::MAKE} $makefiles $makevars")) {
            $log->error();
            exit(1);
        }
        chdir($pkgoutdir);
        $log->result("OK");
    }
 
    ## Check package vignettes.
 
    chdir($pkgoutdir);
 
    my $vignette_dir = &file_path($pkgdir, "inst", "doc");
    if((-d $vignette_dir)
       && &list_files_with_type($vignette_dir, "vignette")) {
	$log->checking(join(" ",
			    ("package vignettes in",
			     &sQuote(&file_path("inst", "doc")))));
	my $any = 0;
 
	## Do PDFs exist for all package vignettes?
	my @vignette_files =
	  &list_files_with_type($vignette_dir, "vignette");
	my @bad_vignettes = ();
	foreach my $file (@vignette_files) {
	    my $pdf_file = $file;
	    $pdf_file =~ s/\.[[:alpha:]]+$/.pdf/;
	    push(@bad_vignettes, $file) unless(-f $pdf_file);
	}
        ## A base package may not have PDFs to avoid blowing out the
	## distribution size.  *Note* that it is assumed that base
	## packages can be woven (i.e., that they only contain
	## "standard" LaTeX).
	if(!$is_base_pkg && scalar(@bad_vignettes) > 0) {
	    $log->warning();
	    $any++;
	    $log->print("Package vignettes without corresponding PDF:\n");
	    $log->print("  " . join("\n  ", @bad_vignettes) . "\n");
	}
 
	## Can we run the code in the vignettes?
	if($opt_install && $opt_vignettes) {
	    ## Should checking the vignettes assume the system default
	    ## packages, or just base?
	    my $Rcmd = "options(warn=1)\nlibrary(tools)\n";
            ## A base package does not get installed during check.
	    if(!$is_base_pkg && $opt_install) {
		$Rcmd .= "checkVignettes(package = \"${pkgname}\", " .
		         "lib.loc = \"${library}\", " .
		         "workdir = \"src\"";
	    }
	    else {
		$Rcmd .= "checkVignettes(dir = \"${pkgdir}\"";
	    }
	    $Rcmd .= ", weave = FALSE" if(!$R_check_weave_vignettes);
	    $Rcmd .= ")\n";
	    my @out = R_runR($Rcmd, "${R_opts} --quiet");
	    ## Vignette could redefine the prompt, e.g. to 'R>' ...
	    @out = grep(!/^[[:alnum:]]*\>/, @out);
	    ## Or to "empty".  As empty lines in the output will most
	    ## likely not indicate a problem ...
	    @out = grep(!/^[[:space:]]*$/, @out);
	    if(scalar(@out) > 0) {
		$log->warning() unless($any);
		$any++;
		$log->print(join("\n", @out) . "\n");
	    }
	}
 
	$log->result("OK") unless($any);
    }
 
    ## Run LaTeX on the manual.
 
    if($opt_latex) {
        my $latex_dir = &file_path($library, $pkgname, "latex");
	if(-d $latex_dir) {
	    $ENV{'TEXINPUTS'} =
	      env_path(&file_path($R::Vars::R_SHARE_DIR, "texmf"),
		       $ENV{'TEXINPUTS'});
            my $is_zipped = 0;
            # latex files might have been zipped
            if(-f &file_path($latex_dir, "Rhelp.zip")) {
                $is_zipped = 1;
		my $UNZIP = &R_getenv("R_UNZIPCMD", "unzip");
		my $latex_file = &file_path($latex_dir, "Rhelp.zip");
		$cmd = join(" ",
			    ("$UNZIP", "-q",
			     &shell_quote_file_path($latex_file),
			     "-d",
			     &shell_quote_file_path($latex_dir)));
                if(R_system($cmd)) {
		    $log->error();
		    $log->print("Unzipping latex files failed.\n");
		    exit(1);
                }
            }
	    $log->creating("${pkgname}-manual.tex");
	    my @tex_files = &list_files_with_exts($latex_dir, "tex");
	    my %encodings;
	    foreach my $file (@tex_files) {
		open(FILE, "< $file")
		  or die("Error: cannot open file '$file' for reading\n");
		while(<FILE>) {
		    if (/^\\inputencoding/) {
			$enc = $_;
			chomp $enc;
			$enc =~ s/^\\inputencoding{(.*)}/\1/;
			$encodings{$enc} = $enc;
		    }
		}
		close(FILE);
	    }
	    my $encs = "";
	    if (scalar(%encodings)) {
		$encs = "\\usepackage[" . join(",", values %encodings) .
		    "]{inputenc}";
	    }
	    open(MANUAL, "> ${pkgname}-manual.tex")
	      or die("Error: cannot open file '${pkgname}-manual.tex'" .
		     "for writing\n");
	    print MANUAL "\\documentclass\{article\}\n" . $encs .
		"\\usepackage[ae,hyper]\{Rd\}\n\\begin\{document\}\n";
	    foreach my $file (@tex_files) {
		open(FILE, "< $file")
		  or die("Error: cannot open file '$file' for reading\n");
		while(<FILE>) {
		    print MANUAL $_;
		}
		close(FILE);
	    }
	    print MANUAL "\\end\{document\}\n";
	    close(MANUAL);
            if($is_zipped) {
		unlink(&list_files_with_exts($latex_dir, "tex"));
            }
	    $log->result("OK");
	    if($HAVE_LATEX) {
		$log->checking("${pkgname}-manual.tex");
		## <NOTE>
		## We use \nonstopmode{} so that LaTeX really gives an
	        ## error (and returns) if something is wrong, and all
	        ## info goes to ${pkgname}-manual.log.
		## We also suppress all output from running LaTeX.
                ## We could also write stdout to a tempfile and replay
                ## this in case of problems.  But does this really help?
		my $cmd = "${R::Vars::LATEX}";
		if($WINDOWS) {
		    ## check if we have MiKTeX and call latex accordingly
		    ## (can't do this in R::Vars::LATEX as we need R::Utils.)
		    my $Rout = R_tempfile("Rlatex");
		    my $cmd2 = "$cmd --version > ${Rout}";
		    R_system($cmd2);
		    my $is_miktex = 0;
		    open ROUT, "< $Rout";
		    while (<ROUT>) {
			chomp;
			$is_miktex = 1 if /^MiKTeX/;
		    }
		    close ROUT;
		    unlink($Rout);
		    $out =~ s/\w//;
		    if($is_miktex) {
			my $R_HOME = $ENV{"R_HOME"};
			$cmd .= " --include-directory=$R_HOME/share/texmf";
		    }
		}
		$cmd .= " '\\nonstopmode{}\\input{${pkgname}-manual.tex}'";
		$cmd .= " >/dev/null 2>&1";
		## </NOTE>
		if(R_system($cmd)) {
		    $log->error();
		    $log->print("LaTeX errors when creating DVI version.\n");
		    $log->print("This typically indicates Rd problems.\n");
		    ## If possible, indicate the problems found.
		    ## GNU grep rather usefully has a '-A' option for
		    ## controlling the number of lines of trailing
		    ## context after matching lines (not POSIX; maybe
		    ## sed could do this?).  Not sure how to do this in
		    ## Perl.  For the time being, try 'grep -A', and
		    ## give no additional info if this fails.
		    my $out = R_tempfile("gout");
		    my $cmd = "grep -A4 '^!' ${pkgname}-manual.log";
		    $cmd .= " > ${out} 2>/dev/null";
		    if(!R_system($cmd)) {
			$log->print("LaTeX errors found:\n\n");
			$log->print(join("\n", &read_lines("${out}")) .
				    "\n");
		    }
		    unlink($out);
		    exit(1);
		}
		$log->result("OK");
	    }
	}
	else {
	    if($HAVE_LATEX) {
		$log->checking("DVI version of manual");
		my $cmd;
		if($WINDOWS) {
		    $cmd = join(" ",
				("Rcmd.exe Rd2dvi --batch --no-preview",
				 "-o ${pkgname}-manual.dvi >/dev/null 2>&1",
				 "$pkgdir"));
		} else {
		    $cmd = join(" ",
				(&shell_quote_file_path("${R::Vars::R_EXE}"),
				 "CMD Rd2dvi --batch --no-preview",
				 "-o ${pkgname}-manual.dvi >/dev/null 2>&1",
				 "$pkgdir"));
		}
		if(R_system($cmd)) {
		    $log->error();
		    $log->print("LaTeX errors when creating DVI version.\n");
		    $log->print("This typically indicates Rd problems.\n");
		    exit(1);
		}
		$log->result("OK");
	    }
	}
    }
}
 

sub usage {
    print STDERR <<END;
Usage: R CMD $name [options] pkgs
 
Check R packages from package sources, which can be directories or
gzipped package 'tar' archives with extension '.tar.gz' or '.tgz'.
 
A variety of diagnostic checks on directory structure, index and
control files are performed.  The package is installed into the log
directory (which includes the translation of all Rd files into several
formats), and the Rd files are tested by LaTeX (if available).  All
examples and tests provided by the package are tested to see if they
run successfully.
 
Options:
  -h, --help            print short help message and exit
  -v, --version         print 'check' version info and exit
  -l, --library=LIB     library directory used for test installation
                        of packages (default is outdir)
  -o, --outdir=DIR      directory used for logfiles, R output, etc.
                        (default is 'pkg.Rcheck' in current directory,
			where 'pkg' is the name of the package checked)
      --no-clean        do not clean outdir before using it
      --no-codoc        do not check for code/documentation mismatches
      --no-examples     do not run the examples in the Rd files
      --no-install      skip installation and associated tests
      --no-tests        do not run code in tests subdirectory
      --no-vignettes    do not check vignettes in Sweave format
      --no-latex        do not run LaTeX on help files
      --use-gct         use 'gctorture(TRUE)' when running examples/tests
      --use-valgrind    use 'valgrind' when running examples/tests/vignettes
      --check-subdirs=default|yes|no
                        run checks on the package subdirectories
			(default is yes for a tarball, no otherwise)
      --rcfile=FILE     read configuration values from FILE
 
By default, all test sections are turned on.
 
Email bug reports to <r-bugs\@r-project.org>.
END
    exit 0;
}

Rev 37487	Rev 37725
1	`#! @PERL@`	1	`#! @PERL@`
2	`#-- perl --`	2	`#-- perl --`
3		3
4	`## Copyright (C) 2000-2006 R Development Core Team`	4	`## Copyright (C) 2000-2006 R Development Core Team`
5	`##`	5	`##`
6	`## This program is free software; you can redistribute it and/or modify`	6	`## This program is free software; you can redistribute it and/or modify`
7	`## it under the terms of the GNU General Public License as published by`	7	`## it under the terms of the GNU General Public License as published by`
8	`## the Free Software Foundation; either version 2, or (at your option)`	8	`## the Free Software Foundation; either version 2, or (at your option)`
9	`## any later version.`	9	`## any later version.`
10	`##`	10	`##`
11	`## This program is distributed in the hope that it will be useful, but`	11	`## This program is distributed in the hope that it will be useful, but`
12	`## WITHOUT ANY WARRANTY; without even the implied warranty of`	12	`## WITHOUT ANY WARRANTY; without even the implied warranty of`
13	`## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU`	13	`## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU`
14	`## General Public License for more details.`	14	`## General Public License for more details.`
15	`##`	15	`##`
16	`## A copy of the GNU General Public License is available via WWW at`	16	`## A copy of the GNU General Public License is available via WWW at`
17	`## http://www.gnu.org/copyleft/gpl.html. You can also obtain it by`	17	`## http://www.gnu.org/copyleft/gpl.html. You can also obtain it by`
18	`## writing to the Free Software Foundation, Inc., 51 Franklin Street,`	18	`## writing to the Free Software Foundation, Inc., 51 Franklin Street,`
19	`## Fifth Floor, Boston, MA 02110-1301 USA.`	19	`## Fifth Floor, Boston, MA 02110-1301 USA.`
20		20
21	`## Send any bug reports to r-bugs@r-project.org`	21	`## Send any bug reports to r-bugs@r-project.org`
22		22
23	`use Cwd;`	23	`use Cwd;`
24	`use File::Basename;`	24	`use File::Basename;`
25	`use File::Copy;`	25	`use File::Copy;`
26	`use File::Find;`	26	`use File::Find;`
27	`use File::Path;`	27	`use File::Path;`
28	`use Getopt::Long;`	28	`use Getopt::Long;`
29	`use IO::File;`	29	`use IO::File;`
30	`use R::Dcf;`	30	`use R::Dcf;`
31	`use R::Logfile;`	31	`use R::Logfile;`
32	`use R::Rdtools;`	32	`use R::Rdtools;`
33	`use R::Utils;`	33	`use R::Utils;`
34	`use R::Vars;`	34	`use R::Vars;`
35	`use Text::Wrap;`	35	`use Text::Wrap;`
36		36
37	`## Don't buffer output.`	37	`## Don't buffer output.`
38	`$\| = 1;`	38	`$\| = 1;`
39		39
40	`my $revision = ' $Rev: 37487 $ ';`	40	`my $revision = ' $Rev: 37725 $ ';`
41	`my $version;`	41	`my $version;`
42	`my $name;`	42	`my $name;`
43	`$revision =~ / ([\d\.]*) /;`	43	`$revision =~ / ([\d\.]*) /;`
44	`$version = $1;`	44	`$version = $1;`
45	`($name = $0) =~ s\|.*/\|\|;`	45	`($name = $0) =~ s\|.*/\|\|;`
46		46
47	`### Options`	47	`### Options`
48	`my $opt_clean = 1;`	48	`my $opt_clean = 1;`
49	`my $opt_examples = 1;`	49	`my $opt_examples = 1;`
50	`my $opt_tests = 1;`	50	`my $opt_tests = 1;`
51	`my $opt_latex = 1;`	51	`my $opt_latex = 1;`
52	`my $opt_use_gct = 0;`	52	`my $opt_use_gct = 0;`
53	`my $opt_codoc = 1;`	53	`my $opt_codoc = 1;`
54	`my $opt_install = 1;`	54	`my $opt_install = 1;`
55	`my $opt_vignettes = 1;`	55	`my $opt_vignettes = 1;`
56	`my $opt_use_valgrind = 0;`	56	`my $opt_use_valgrind = 0;`
57	`my $opt_rcfile = ""; # Only set this if $ENV{"HOME"} is set.`	57	`my $opt_rcfile = ""; # Only set this if $ENV{"HOME"} is set.`
58	`$opt_rcfile = &file_path($ENV{"HOME"}, ".R", "check.conf")`	58	`$opt_rcfile = &file_path($ENV{"HOME"}, ".R", "check.conf")`
59	`if defined($ENV{"HOME"});`	59	`if defined($ENV{"HOME"});`
60	`my $opt_subdirs;`	60	`my $opt_subdirs;`
61		61
62	`my $WINDOWS = ($R::Vars::OSTYPE eq "windows");`	62	`my $WINDOWS = ($R::Vars::OSTYPE eq "windows");`
63		63
64	`R::Vars::error("R_HOME", "R_EXE");`	64	`R::Vars::error("R_HOME", "R_EXE");`
65		65
66	`my @known_options = ("help\|h", "version\|v", "outdir\|o:s", "library\|l:s",`	66	`my @known_options = ("help\|h", "version\|v", "outdir\|o:s", "library\|l:s",`
67	`"no-clean", "no-examples", "no-tests", "no-latex",`	67	`"no-clean", "no-examples", "no-tests", "no-latex",`
68	`"use-gct" => \$opt_use_gct, "no-codoc",`	68	`"use-gct" => \$opt_use_gct, "no-codoc",`
69	`"install=s" => \$opt_install, "no-install",`	69	`"install=s" => \$opt_install, "no-install",`
70	`"no-vignettes", "use-valgrind" => \$opt_use_valgrind,`	70	`"no-vignettes", "use-valgrind" => \$opt_use_valgrind,`
71	`"rcfile=s" => \$opt_rcfile,`	71	`"rcfile=s" => \$opt_rcfile,`
72	`"check-subdirs=s" => \$opt_subdirs);`	72	`"check-subdirs=s" => \$opt_subdirs);`
73	`GetOptions(@known_options) or usage();`	73	`GetOptions(@known_options) or usage();`
74		74
75	`R_version("R add-on package checker", $version) if $opt_version;`	75	`R_version("R add-on package checker", $version) if $opt_version;`
76	`usage() if $opt_help;`	76	`usage() if $opt_help;`
77		77
78	`$opt_clean = 0 if $opt_no_clean;`	78	`$opt_clean = 0 if $opt_no_clean;`
79	`$opt_examples = 0 if $opt_no_examples;`	79	`$opt_examples = 0 if $opt_no_examples;`
80	`$opt_tests = 0 if $opt_no_tests;`	80	`$opt_tests = 0 if $opt_no_tests;`
81	`$opt_latex = 0 if $opt_no_latex;`	81	`$opt_latex = 0 if $opt_no_latex;`
82	`$opt_codoc = 0 if $opt_no_codoc;`	82	`$opt_codoc = 0 if $opt_no_codoc;`
83	`$opt_install = 0 if $opt_no_install;`	83	`$opt_install = 0 if $opt_no_install;`
84	`$opt_vignettes = 0 if $opt_no_vignettes;`	84	`$opt_vignettes = 0 if $opt_no_vignettes;`
85		85
86	`if($opt_install eq "fake") {`	86	`if($opt_install eq "fake") {`
87	`## If we fake installation, then we cannot run any code.`	87	`## If we fake installation, then we cannot run any code.`
88	`$opt_examples = $opt_tests = $opt_vignettes = 0;`	88	`$opt_examples = $opt_tests = $opt_vignettes = 0;`
89	`}`	89	`}`
90	`$opt_install = 0 if($opt_install eq "no");`	90	`$opt_install = 0 if($opt_install eq "no");`
91		91
92	`my $opt_ff_calls = 1;`	92	`my $opt_ff_calls = 1;`
93	`## The neverending story ...`	93	`## The neverending story ...`
94	`## For the time being, allow to turn this off by setting the environment`	94	`## For the time being, allow to turn this off by setting the environment`
95	`## variable _R_CHECK_FF_CALLS_ to a Perl 'null' value.`	95	`## variable _R_CHECK_FF_CALLS_ to a Perl 'null' value.`
96	`if(defined($ENV{"_R_CHECK_FF_CALLS_"})) {`	96	`if(defined($ENV{"_R_CHECK_FF_CALLS_"})) {`
97	`$opt_ff_calls = $ENV{"_R_CHECK_FF_CALLS_"};`	97	`$opt_ff_calls = $ENV{"_R_CHECK_FF_CALLS_"};`
98	`}`	98	`}`
99		99
100	`## Use system default unless explicitly specified otherwise.`	100	`## Use system default unless explicitly specified otherwise.`
101	`$ENV{"R_DEFAULT_PACKAGES"} = "";`	101	`$ENV{"R_DEFAULT_PACKAGES"} = "";`
102		102
103	`### Configurable variables`	103	`### Configurable variables`
104	`my $R_check_use_install_log =`	104	`my $R_check_use_install_log =`
105	`&R_getenv("_R_CHECK_USE_INSTALL_LOG_", "TRUE");`	105	`&R_getenv("_R_CHECK_USE_INSTALL_LOG_", "TRUE");`
106	`my $R_check_subdirs_nocase =`	106	`my $R_check_subdirs_nocase =`
107	`&R_getenv("_R_CHECK_SUBDIRS_NOCASE_", "FALSE");`	107	`&R_getenv("_R_CHECK_SUBDIRS_NOCASE_", "FALSE");`
108	`my $R_check_all_non_ISO_C =`	108	`my $R_check_all_non_ISO_C =`
109	`&R_getenv("_R_CHECK_ALL_NON_ISO_C_", "FALSE");`	109	`&R_getenv("_R_CHECK_ALL_NON_ISO_C_", "FALSE");`
110	`my $R_check_weave_vignettes =`	110	`my $R_check_weave_vignettes =`
111	`&R_getenv("_R_CHECK_WEAVE_VIGNETTES_", "TRUE");`	111	`&R_getenv("_R_CHECK_WEAVE_VIGNETTES_", "TRUE");`
112	`my $R_check_subdirs_strict =`	112	`my $R_check_subdirs_strict =`
113	`&R_getenv("_R_CHECK_SUBDIRS_STRICT_", "default");`	113	`&R_getenv("_R_CHECK_SUBDIRS_STRICT_", "default");`
114		114
115	`## Maybe move basic configuration (and documentation) to`	115	`## Maybe move basic configuration (and documentation) to`
116	`## &file_path($R::Vars::R_HOME, "etc", "check.conf")`	116	`## &file_path($R::Vars::R_HOME, "etc", "check.conf")`
117	`## eventually ...`	117	`## eventually ...`
118	`for my $file ($opt_rcfile) {`	118	`for my $file ($opt_rcfile) {`
119	`if(-r $file) {`	119	`if(-r $file) {`
120	`open(FILE, "< $file")`	120	`open(FILE, "< $file")`
121	`or die "Error: cannot open file '$file' for reading\n";`	121	`or die "Error: cannot open file '$file' for reading\n";`
122	`my @lines = <FILE>;`	122	`my @lines = <FILE>;`
123	`close(FILE);`	123	`close(FILE);`
124	`eval("@lines");`	124	`eval("@lines");`
125	`die "Error: failed to eval config file '$file'\n$@\n" if ($@);`	125	`die "Error: failed to eval config file '$file'\n$@\n" if ($@);`
126	`## <NOTE>`	126	`## <NOTE>`
127	`## We prefer the above to the usual recommendation`	127	`## We prefer the above to the usual recommendation`
128	`## unless ($return = do($file)) {`	128	`## unless ($return = do($file)) {`
129	`## warn "couldn't parse $file: $@" if $@;`	129	`## warn "couldn't parse $file: $@" if $@;`
130	`## warn "couldn't do $file: $!" unless defined $return;`	130	`## warn "couldn't do $file: $!" unless defined $return;`
131	`## warn "couldn't run $file" unless $return;`	131	`## warn "couldn't run $file" unless $return;`
132	`## }`	132	`## }`
133	`## as do(FILE) cannot see lexicals in the enclosing scope.`	133	`## as do(FILE) cannot see lexicals in the enclosing scope.`
134	`## </NOTE>`	134	`## </NOTE>`
135	`}`	135	`}`
136	`}`	136	`}`
137		137
138	`$R_check_use_install_log =`	138	`$R_check_use_install_log =`
139	`&config_val_to_logical($R_check_use_install_log);`	139	`&config_val_to_logical($R_check_use_install_log);`
140	`$R_check_subdirs_nocase =`	140	`$R_check_subdirs_nocase =`
141	`&config_val_to_logical($R_check_subdirs_nocase);`	141	`&config_val_to_logical($R_check_subdirs_nocase);`
142	`$R_check_all_non_ISO_C =`	142	`$R_check_all_non_ISO_C =`
143	`&config_val_to_logical($R_check_all_non_ISO_C);`	143	`&config_val_to_logical($R_check_all_non_ISO_C);`
144	`$R_check_weave_vignettes =`	144	`$R_check_weave_vignettes =`
145	`&config_val_to_logical($R_check_weave_vignettes);`	145	`&config_val_to_logical($R_check_weave_vignettes);`
146		146
147	`$opt_subdirs = $R_check_subdirs_strict if $opt_subdirs eq "";`	147	`$opt_subdirs = $R_check_subdirs_strict if $opt_subdirs eq "";`
148		148
149	`my $startdir = R_cwd();`	149	`my $startdir = R_cwd();`
150	`$opt_outdir = $startdir unless $opt_outdir;`	150	`$opt_outdir = $startdir unless $opt_outdir;`
151	`chdir($opt_outdir)`	151	`chdir($opt_outdir)`
152	`or die "Error: cannot change to directory '$opt_outdir'\n";`	152	`or die "Error: cannot change to directory '$opt_outdir'\n";`
153	`my $outdir = R_cwd();`	153	`my $outdir = R_cwd();`
154	`chdir($startdir);`	154	`chdir($startdir);`
155		155
156	`my $R_LIBS = $ENV{'R_LIBS'};`	156	`my $R_LIBS = $ENV{'R_LIBS'};`
157	`my $library;`	157	`my $library;`
158	`if($opt_library) {`	158	`if($opt_library) {`
159	`chdir($opt_library)`	159	`chdir($opt_library)`
160	`or die "Error: cannot change to directory '$opt_library'\n";`	160	`or die "Error: cannot change to directory '$opt_library'\n";`
161	`$library = R_cwd();`	161	`$library = R_cwd();`
162	`$ENV{'R_LIBS'} = env_path($library, $R_LIBS);`	162	`$ENV{'R_LIBS'} = env_path($library, $R_LIBS);`
163		163
164	`chdir($startdir);`	164	`chdir($startdir);`
165	`}`	165	`}`
166		166
167	`my $tar = R_getenv("TAR", "tar");`	167	`my $tar = R_getenv("TAR", "tar");`
168	`my $gzip = R_getenv("R_GZIPCMD", "gzip");`	168	`my $gzip = R_getenv("R_GZIPCMD", "gzip");`
169		169
170	`my $R_opts = "--vanilla";`	170	`my $R_opts = "--vanilla";`
171		171
172	`if($opt_latex) {`	172	`if($opt_latex) {`
173	`my $log = new R::Logfile();`	173	`my $log = new R::Logfile();`
174	`$log->checking("for working latex");`	174	`$log->checking("for working latex");`
175	`open(TEXFILE,`	175	`open(TEXFILE,`
176	`"> " . &file_path(${R::Vars::TMPDIR}, "Rtextest$$.tex"))`	176	`"> " . &file_path(${R::Vars::TMPDIR}, "Rtextest$$.tex"))`
177	`or die "Error: cannot open file 'Rtextest$$.tex' for writing\n";`	177	`or die "Error: cannot open file 'Rtextest$$.tex' for writing\n";`
178	`print TEXFILE "\\documentclass\{article\}\\begin\{document\}" .`	178	`print TEXFILE "\\documentclass\{article\}\\begin\{document\}" .`
179	`"test\\end\{document\}\n";`	179	`"test\\end\{document\}\n";`
180	`close(TEXFILE);`	180	`close(TEXFILE);`
181	`chdir($R::Vars::TMPDIR);`	181	`chdir($R::Vars::TMPDIR);`
182	`if(R_system("${R::Vars::LATEX} Rtextest$$ > Rtextest$$.out")) {`	182	`if(R_system("${R::Vars::LATEX} Rtextest$$ > Rtextest$$.out")) {`
183	`$log->result("NO");`	183	`$log->result("NO");`
184	`$HAVE_LATEX = 0;`	184	`$HAVE_LATEX = 0;`
185	`} else {`	185	`} else {`
186	`$log->result("OK");`	186	`$log->result("OK");`
187	`$HAVE_LATEX = 1;`	187	`$HAVE_LATEX = 1;`
188	`}`	188	`}`
189	`unlink(<Rtextest$$.*>);`	189	`unlink(<Rtextest$$.*>);`
190	`chdir($startdir);`	190	`chdir($startdir);`
191	`$log->close();`	191	`$log->close();`
192	`}`	192	`}`
193		193
194	`## This is the main loop over all packages to be checked.`	194	`## This is the main loop over all packages to be checked.`
195	`(scalar(@ARGV) > 0) or die "Error: no packages were specified\n";`	195	`(scalar(@ARGV) > 0) or die "Error: no packages were specified\n";`
196	`foreach my $pkg (@ARGV) {`	196	`foreach my $pkg (@ARGV) {`
197	`## $pkg should be the path to the package (bundle) root source`	197	`## $pkg should be the path to the package (bundle) root source`
198	`## directory, either absolute or relative to $startdir.`	198	`## directory, either absolute or relative to $startdir.`
199	`## As from 2.1.0 it can also be a tarball`	199	`## As from 2.1.0 it can also be a tarball`
200		200
201	`## $pkgdir is the corresponding absolute path.`	201	`## $pkgdir is the corresponding absolute path.`
202	`## $pkgname is the name of the package (bundle).`	202	`## $pkgname is the name of the package (bundle).`
203	`chdir($startdir);`	203	`chdir($startdir);`
204	`$pkg =~ s+/$++; # strip any trailing '/'`	204	`$pkg =~ s+/$++; # strip any trailing '/'`
205	`my $pkgname = basename($pkg);`	205	`my $pkgname = basename($pkg);`
206		206
207	`my $thispkg_subdirs = $opt_subdirs;`	207	`my $thispkg_subdirs = $opt_subdirs;`
208	`## is this a tar archive?`	208	`## is this a tar archive?`
209	`my $istar = 0;`	209	`my $istar = 0;`
210	`if($pkgname =~ /\.tar\.gz$/ \|\| $pkgname =~ /\.tgz$/) {`	210	`if($pkgname =~ /\.tar\.gz$/ \|\| $pkgname =~ /\.tgz$/) {`
211	`$pkgname =~ s/\.tar\.gz$//;`	211	`$pkgname =~ s/\.tar\.gz$//;`
212	`$pkgname =~ s/\.tgz$//;`	212	`$pkgname =~ s/\.tgz$//;`
213	`$pkgname =~ s/_[0-9\.-]*$//;`	213	`$pkgname =~ s/_[0-9\.-]*$//;`
214	`$istar = 1;`	214	`$istar = 1;`
215	`$thispkg_subdirs = "yes-maybe" if $thispkg_subdirs eq "default";`	215	`$thispkg_subdirs = "yes-maybe" if $thispkg_subdirs eq "default";`
216	`} else {`	216	`} else {`
217	`$thispkg_subdirs = "no" if $thispkg_subdirs eq "default";`	217	`$thispkg_subdirs = "no" if $thispkg_subdirs eq "default";`
218	`}`	218	`}`
219		219
220	`my $pkgoutdir = &file_path($outdir, "$pkgname.Rcheck");`	220	`my $pkgoutdir = &file_path($outdir, "$pkgname.Rcheck");`
221	`rmtree($pkgoutdir) if ($opt_clean && (-d $pkgoutdir)) ;`	221	`rmtree($pkgoutdir) if ($opt_clean && (-d $pkgoutdir)) ;`
222	`if(!(-d $pkgoutdir)) {`	222	`if(!(-d $pkgoutdir)) {`
223	`mkdir($pkgoutdir, 0755)`	223	`mkdir($pkgoutdir, 0755)`
224	`or die("Error: cannot create directory '$pkgoutdir'\n");`	224	`or die("Error: cannot create directory '$pkgoutdir'\n");`
225	`}`	225	`}`
226		226
227	`if($istar) {`	227	`if($istar) {`
228	`my $dir = &file_path("$pkgoutdir", "00_pkg_src");`	228	`my $dir = &file_path("$pkgoutdir", "00_pkg_src");`
229	`mkdir($dir, 0755)`	229	`mkdir($dir, 0755)`
230	`or die("Error: cannot create directory '$dir'\n");`	230	`or die("Error: cannot create directory '$dir'\n");`
231	`if($WINDOWS) {`	231	`if($WINDOWS) {`
232	`## workaround for paths in Cygwin tar`	232	`## workaround for paths in Cygwin tar`
233	`$pkg =~ s+^([A-Za-z]):+/cygdrive/\1+;`	233	`$pkg =~ s+^([A-Za-z]):+/cygdrive/\1+;`
234	`}`	234	`}`
235	`## this requires GNU tar: ATT 'tar x' does not support -C.`	235	`## this requires GNU tar: ATT 'tar x' does not support -C.`
236	`if(R_system("$gzip -dc '$pkg' \| $tar -xf - -C $dir")) {`	236	`if(R_system("$gzip -dc '$pkg' \| $tar -xf - -C $dir")) {`
237	`die "Error: cannot untar $pkg\n";}`	237	`die "Error: cannot untar $pkg\n";}`
238	`$pkg = &file_path($dir, $pkgname);`	238	`$pkg = &file_path($dir, $pkgname);`
239	`}`	239	`}`
240		240
241	`$pkg =~ s/\/$//;`	241	`$pkg =~ s/\/$//;`
242	`(-d $pkg) or die "Error: package dir '$pkg' does not exist\n";`	242	`(-d $pkg) or die "Error: package dir '$pkg' does not exist\n";`
243	`chdir($pkg)`	243	`chdir($pkg)`
244	`or die "Error: cannot change to directory '$pkg'\n";`	244	`or die "Error: cannot change to directory '$pkg'\n";`
245	`my $pkgdir = R_cwd();`	245	`my $pkgdir = R_cwd();`
246	`## my $pkgname = basename($pkgdir);`	246	`## my $pkgname = basename($pkgdir);`
247	`my $thispkg_src_subdir = $thispkg_subdirs;`	247	`my $thispkg_src_subdir = $thispkg_subdirs;`
248	`if($thispkg_src_subdir eq "yes-maybe") {`	248	`if($thispkg_src_subdir eq "yes-maybe") {`
249	`## now see if there is a 'configure' file`	249	`## now see if there is a 'configure' file`
250	`## configure files are only used if executable, but`	250	`## configure files are only used if executable, but`
251	`## -x is always false on Windows.`	251	`## -x is always false on Windows.`
252	`if($WINDOWS) {`	252	`if($WINDOWS) {`
253	`$thispkg_src_subdir = "no" if (-f "configure");`	253	`$thispkg_src_subdir = "no" if (-f "configure");`
254	`} else {`	254	`} else {`
255	`$thispkg_src_subdir = "no" if (-x "configure");`	255	`$thispkg_src_subdir = "no" if (-x "configure");`
256	`}`	256	`}`
257	`}`	257	`}`
258	`chdir($startdir);`	258	`chdir($startdir);`
259		259
260	`$log = new R::Logfile(&file_path($pkgoutdir, "00check.log"));`	260	`$log = new R::Logfile(&file_path($pkgoutdir, "00check.log"));`
261	`$log->message("using log directory '$pkgoutdir'");`	261	`$log->message("using log directory '$pkgoutdir'");`
262	`my @out = R_runR("cat(R.version.string, '\n', sep='')",`	262	`my @out = R_runR("cat(R.version.string, '\n', sep='')",`
263	`"--slave --vanilla");`	263	`"--slave --vanilla");`
264	`$log->message("using @out");`	264	`$log->message("using @out");`
265		265
266	`if(!$opt_library) {`	266	`if(!$opt_library) {`
267	`$library = $pkgoutdir;`	267	`$library = $pkgoutdir;`
268	`$ENV{'R_LIBS'} = env_path($library, $R_LIBS);`	268	`$ENV{'R_LIBS'} = env_path($library, $R_LIBS);`
269	`}`	269	`}`
270	`if($WINDOWS) { ## need to avoid spaces in $library`	270	`if($WINDOWS) { ## need to avoid spaces in $library`
271	`$library = Win32::GetShortPathName($library) if $library =~ / /;`	271	`$library = Win32::GetShortPathName($library) if $library =~ / /;`
272	`}`	272	`}`
273		273
274	`my $description;`	274	`my $description;`
275	`my $is_base_pkg = 0;`	275	`my $is_base_pkg = 0;`
276	`my $is_bundle = 0;`	276	`my $is_bundle = 0;`
277	`my $package_or_bundle = "package";`	277	`my $package_or_bundle = "package";`
278	`my $package_or_bundle_name;`	278	`my $package_or_bundle_name;`
279	`## Package sources from the R distribution are special. They have a`	279	`## Package sources from the R distribution are special. They have a`
280	`## 'DESCRIPTION.in' file (instead of 'DESCRIPTION'), with Version`	280	`## 'DESCRIPTION.in' file (instead of 'DESCRIPTION'), with Version`
281	`## field containing '@VERSION@' for substitution by configure. We`	281	`## field containing '@VERSION@' for substitution by configure. We`
282	`## test for such packages by looking for 'DESCRIPTION.in' with`	282	`## test for such packages by looking for 'DESCRIPTION.in' with`
283	`## Priority 'base', and skip the installation test for such`	283	`## Priority 'base', and skip the installation test for such`
284	`## packages.`	284	`## packages.`
285	`if(-r &file_path($pkgdir, "DESCRIPTION.in")) {`	285	`if(-r &file_path($pkgdir, "DESCRIPTION.in")) {`
286	`$description =`	286	`$description =`
287	`new R::Dcf(&file_path($pkgdir, "DESCRIPTION.in"));`	287	`new R::Dcf(&file_path($pkgdir, "DESCRIPTION.in"));`
288	`if($description->{"Priority"} eq "base") {`	288	`if($description->{"Priority"} eq "base") {`
289	`$log->message("looks like '${pkgname}' is a base package");`	289	`$log->message("looks like '${pkgname}' is a base package");`
290	`$log->message("skipping installation test");`	290	`$log->message("skipping installation test");`
291	`$is_base_pkg = 1;`	291	`$is_base_pkg = 1;`
292	`}`	292	`}`
293	`}`	293	`}`
294		294
295	`if(!$is_base_pkg) {`	295	`if(!$is_base_pkg) {`
296	`$log->checking(join("",`	296	`$log->checking(join("",`
297	`("for file '",`	297	`("for file '",`
298	`&file_path($pkgname, "DESCRIPTION"),`	298	`&file_path($pkgname, "DESCRIPTION"),`
299	`"'")));`	299	`"'")));`
300	`if(-r &file_path($pkgdir, "DESCRIPTION")) {`	300	`if(-r &file_path($pkgdir, "DESCRIPTION")) {`
301	`$description =`	301	`$description =`
302	`new R::Dcf(&file_path($pkgdir, "DESCRIPTION"));`	302	`new R::Dcf(&file_path($pkgdir, "DESCRIPTION"));`
303	`$log->result("OK");`	303	`$log->result("OK");`
304	`}`	304	`}`
305	`else {`	305	`else {`
306	`$log->result("NO");`	306	`$log->result("NO");`
307	`exit(1);`	307	`exit(1);`
308	`}`	308	`}`
309	`if($description->{"Type"}) { # standard packages do not have this`	309	`if($description->{"Type"}) { # standard packages do not have this`
310	`$log->checking("extension type");`	310	`$log->checking("extension type");`
311	`$log->result($description->{"Type"});`	311	`$log->result($description->{"Type"});`
312	`if($description->{"Type"} ne "Package") {`	312	`if($description->{"Type"} ne "Package") {`
313	`$log->print("Only Type = Package extensions can be checked.\n");`	313	`$log->print("Only Type = Package extensions can be checked.\n");`
314	`exit(0);`	314	`exit(0);`
315	`}`	315	`}`
316	`}`	316	`}`
317		317
318	`if($description->{"Bundle"}) {`	318	`if($description->{"Bundle"}) {`
319	`$is_bundle = 1;`	319	`$is_bundle = 1;`
320	`$log->message("looks like '${pkgname}' is a package bundle");`	320	`$log->message("looks like '${pkgname}' is a package bundle");`
321	`$package_or_bundle = "bundle";`	321	`$package_or_bundle = "bundle";`
322	`$package_or_bundle_name = $description->{"Bundle"};`	322	`$package_or_bundle_name = $description->{"Bundle"};`
323	`}`	323	`}`
324	`else {`	324	`else {`
325	`$package_or_bundle_name = $description->{"Package"};`	325	`$package_or_bundle_name = $description->{"Package"};`
326	`}`	326	`}`
327	`$log->message("this is $package_or_bundle " .`	327	`$log->message("this is $package_or_bundle " .`
328	`"'$package_or_bundle_name' " .`	328	`"'$package_or_bundle_name' " .`
329	`"version '$description->{\"Version\"}'");`	329	`"version '$description->{\"Version\"}'");`
330		330
331	`## Check package dependencies.`	331	`## Check package dependencies.`
332		332
333	`## <NOTE>`	333	`## <NOTE>`
334	`## We want to check for dependencies early, since missing`	334	`## We want to check for dependencies early, since missing`
335	`## dependencies may make installation fail, and in any case we`	335	`## dependencies may make installation fail, and in any case we`
336	`## give up if they are missing. But we don't check them if`	336	`## give up if they are missing. But we don't check them if`
337	`## we are not going to install and hence not run any code.`	337	`## we are not going to install and hence not run any code.`
338	`## </NOTE>`	338	`## </NOTE>`
339		339
340	`if($opt_install) {`	340	`if($opt_install) {`
341	`## Try figuring out whether the package dependencies can be`	341	`## Try figuring out whether the package dependencies can be`
342	`## resolved at run time.`	342	`## resolved at run time.`
343	`## Ideally, the installation mechanism would do this,`	343	`## Ideally, the installation mechanism would do this,`
344	`## and we also do not check versions ... also see whether vignette`	344	`## and we also do not check versions ... also see whether vignette`
345	`## and namespace package dependencies are recorded in DESCRIPTION.`	345	`## and namespace package dependencies are recorded in DESCRIPTION.`
346		346
347	`## <NOTE>`	347	`## <NOTE>`
348	`## We are not checking base packages here, so all packages do`	348	`## We are not checking base packages here, so all packages do`
349	`## have a description file. Bundles should have dependencies`	349	`## have a description file. Bundles should have dependencies`
350	`## only at the top level to be usable by install.packages and`	350	`## only at the top level to be usable by install.packages and`
351	## friends, and `Writing R Extensions' requires this.	351	## friends, and `Writing R Extensions' requires this.
352	`## </NOTE>`	352	`## </NOTE>`
353		353
354	`$log->checking("package dependencies");`	354	`$log->checking("package dependencies");`
355	`## Everything listed in Depends or Suggests or Imports`	355	`## Everything listed in Depends or Suggests or Imports`
356	`## should be available for successfully running R CMD check.`	356	`## should be available for successfully running R CMD check.`
357	`## \VignetteDepends{} entries not "required" by the package code`	357	`## \VignetteDepends{} entries not "required" by the package code`
358	`## must be in Suggests. Note also that some of us think that a`	358	`## must be in Suggests. Note also that some of us think that a`
359	`## package vignette must require its own package, which OTOH is`	359	`## package vignette must require its own package, which OTOH is`
360	`## not required in the package DESCRIPTION file.`	360	`## not required in the package DESCRIPTION file.`
361	`## Namespace imports must really be in Depends.`	361	`## Namespace imports must really be in Depends.`
362	`my $Rcmd = "tools:::.check_package_depends(\"${pkgdir}\")\n";`	362	`my $Rcmd = "tools:::.check_package_depends(\"${pkgdir}\")\n";`
363	`my @out = R_runR($Rcmd, "${R_opts} --quiet",`	363	`my @out = R_runR($Rcmd, "${R_opts} --quiet",`
364	`"R_DEFAULT_PACKAGES=NULL");`	364	`"R_DEFAULT_PACKAGES=NULL");`
365	`@out = grep(!/^\>/, @out);`	365	`@out = grep(!/^\>/, @out);`
366	`if(scalar(@out) > 0) {`	366	`if(scalar(@out) > 0) {`
367	`$log->error();`	367	`$log->error();`
368	`$log->print(join("\n", @out) . "\n");`	368	`$log->print(join("\n", @out) . "\n");`
369	`$log->print(wrap("", "", @msg_DESCRIPTION));`	369	`$log->print(wrap("", "", @msg_DESCRIPTION));`
370	`exit(1);`	370	`exit(1);`
371	`} else {`	371	`} else {`
372	`$log->result("OK");`	372	`$log->result("OK");`
373	`}`	373	`}`
374	`}`	374	`}`
375		375
376	`## <NOTE>`	376	`## <NOTE>`
377	`## This check should be adequate, but would not catch a manually`	377	`## This check should be adequate, but would not catch a manually`
378	`## installed package, nor one installed prior to 1.4.0.`	378	`## installed package, nor one installed prior to 1.4.0.`
379	`## </NOTE>`	379	`## </NOTE>`
380	`$log->checking("if this is a source $package_or_bundle");`	380	`$log->checking("if this is a source $package_or_bundle");`
381	`if(defined($description->{"Built"})) {`	381	`if(defined($description->{"Built"})) {`
382	`$log->error();`	382	`$log->error();`
383	`$log->print("Only source packages can be checked.\n");`	383	`$log->print("Only source packages can be checked.\n");`
384	`exit(1);`	384	`exit(1);`
385	`}`	385	`}`
386	`elsif($opt_install !~ /^check/) {`	386	`elsif($opt_install !~ /^check/) {`
387	`## Check for package/bundle 'src' subdirectories with object`	387	`## Check for package/bundle 'src' subdirectories with object`
388	`## files (but not if installation was already performed).`	388	`## files (but not if installation was already performed).`
389	`my $any;`	389	`my $any;`
390	`my $pat = "(a\|o\|[ls][ao]\|sl\|obj)"; # Object file extensions.`	390	`my $pat = "(a\|o\|[ls][ao]\|sl\|obj)"; # Object file extensions.`
391	`my @dirs;`	391	`my @dirs;`
392	`if($is_bundle) {`	392	`if($is_bundle) {`
393	`foreach my $ppkg (split(/\s+/,`	393	`foreach my $ppkg (split(/\s+/,`
394	`$description->{"Contains"})) {`	394	`$description->{"Contains"})) {`
395	`push(@dirs, &file_path($ppkg, "src"));`	395	`push(@dirs, &file_path($ppkg, "src"));`
396	`}`	396	`}`
397	`}`	397	`}`
398	`else {`	398	`else {`
399	`@dirs = ("src");`	399	`@dirs = ("src");`
400	`}`	400	`}`
401	`foreach my $dir (@dirs) {`	401	`foreach my $dir (@dirs) {`
402	`if((-d &file_path($pkgdir, $dir))`	402	`if((-d &file_path($pkgdir, $dir))`
403	`&& &list_files_with_exts(&file_path($pkgdir, $dir),`	403	`&& &list_files_with_exts(&file_path($pkgdir, $dir),`
404	`$pat)) {`	404	`$pat)) {`
405	`$log->warning() unless $any;`	405	`$log->warning() unless $any;`
406	`$any++;`	406	`$any++;`
407	`$dir = &file_path($pkgname, $dir);`	407	`$dir = &file_path($pkgname, $dir);`
408	`$log->print("Subdirectory '$dir' " .`	408	`$log->print("Subdirectory '$dir' " .`
409	`"contains object files.\n");`	409	`"contains object files.\n");`
410	`}`	410	`}`
411	`}`	411	`}`
412		412
413	`if($thispkg_src_subdir ne "no") {`	413	`if($thispkg_src_subdir ne "no") {`
414	`foreach my $dir (@dirs) {`	414	`foreach my $dir (@dirs) {`
415	`if((-d &file_path($pkgdir, $dir))) {`	415	`if((-d &file_path($pkgdir, $dir))) {`
416	`chdir(&file_path($pkgdir, $dir));`	416	`chdir(&file_path($pkgdir, $dir));`
417	`if(!(-f "Makefile") && !(-f "Makefile.win")) {`	417	`if(!(-f "Makefile") && !(-f "Makefile.win")) {`
418	`opendir(DIR, ".") or die "cannot opendir $dir: $!";`	418	`opendir(DIR, ".") or die "cannot opendir $dir: $!";`
419	`@srcfiles = grep {`	419	`@srcfiles = grep {`
420	`!(/\.([Ccfh]\|cc\|cpp\|f90\|f95)$/`	420	`!(/\.([Ccfh]\|cc\|cpp\|f90\|f95)$/`
421	`\|\| /^Makevars/ \|\| /-win\.def$/ )`	421	`\|\| /^Makevars/ \|\| /-win\.def$/ )`
422	`&& -f "$_" } readdir(DIR);`	422	`&& -f "$_" } readdir(DIR);`
423	`closedir(DIR);`	423	`closedir(DIR);`
424	`if(@srcfiles) {`	424	`if(@srcfiles) {`
425	`$log->warning() unless $any;`	425	`$log->warning() unless $any;`
426	`$any++;`	426	`$any++;`
427	`$log->print("Subdirectory '$dir' contains:\n");`	427	`$log->print("Subdirectory '$dir' contains:\n");`
428	`$log->print(wrap(" ", " ",`	428	`$log->print(wrap(" ", " ",`
429	`join(" ", sort @srcfiles) . "\n"));`	429	`join(" ", sort @srcfiles) . "\n"));`
430	`$log->print(wrap("", "",`	430	`$log->print(wrap("", "",`
431	`("These are unlikely file names",`	431	`("These are unlikely file names",`
432	`"for src files.\n")));`	432	`"for src files.\n")));`
433	`}`	433	`}`
434	`}`	434	`}`
435	`chdir($startdir);`	435	`chdir($startdir);`
436	`}`	436	`}`
437	`}`	437	`}`
438	`}`	438	`}`
439	`$log->result("OK") unless $any;`	439	`$log->result("OK") unless $any;`
440	`}`	440	`}`
441	`else {`	441	`else {`
442	`$log->result("OK");`	442	`$log->result("OK");`
443	`}`	443	`}`
444		444
445	`## Option '--no-install' turns off installation and the tests`	445	`## Option '--no-install' turns off installation and the tests`
446	`## which require the package to be installed. When testing`	446	`## which require the package to be installed. When testing`
447	`## recommended packages bundled with R we can skip installation,`	447	`## recommended packages bundled with R we can skip installation,`
448	`## and do so if '--install=skip' was given. If command line`	448	`## and do so if '--install=skip' was given. If command line`
449	`## option '--install' is of the form 'check:FILE', it is assumed`	449	`## option '--install' is of the form 'check:FILE', it is assumed`
450	`## that installation was already performed with stdout/stderr to`	450	`## that installation was already performed with stdout/stderr to`
451	`## FILE, the contents of which need to be checked (without`	451	`## FILE, the contents of which need to be checked (without`
452	`## repeating the installation).`	452	`## repeating the installation).`
453	`## <NOTE>`	453	`## <NOTE>`
454	`## In this case, one also needs to specify where the package`	454	`## In this case, one also needs to specify where the package`
455	`## was installed to using command line option '--library'.`	455	`## was installed to using command line option '--library'.`
456	`## Perhaps we should check for that, although '--install=check'`	456	`## Perhaps we should check for that, although '--install=check'`
457	`## is really only meant for repository maintainers.`	457	`## is really only meant for repository maintainers.`
458	`## </NOTE>`	458	`## </NOTE>`
459	`if($opt_install) {`	459	`if($opt_install) {`
460	`if($opt_install eq "skip") {`	460	`if($opt_install eq "skip") {`
461	`$log->message("skipping installation test");`	461	`$log->message("skipping installation test");`
462	`}`	462	`}`
463	`else {`	463	`else {`
464	`my $use_install_log =`	464	`my $use_install_log =`
465	`(($opt_install =~ /^check/) \|\|`	465	`(($opt_install =~ /^check/) \|\|`
466	`$R_check_use_install_log \|\|`	466	`$R_check_use_install_log \|\|`
467	`!(-t STDIN && -t STDOUT));`	467	`!(-t STDIN && -t STDOUT));`
468	`my $INSTALL_opts = "";`	468	`my $INSTALL_opts = "";`
469	`$INSTALL_opts = "--fake" if($opt_install eq "fake");`	469	`$INSTALL_opts = "--fake" if($opt_install eq "fake");`
470	`my $cmd;`	470	`my $cmd;`
471	`if($WINDOWS) {`	471	`if($WINDOWS) {`
472	`$cmd = join(" ",`	472	`$cmd = join(" ",`
473	`("Rcmd.exe INSTALL -l",`	473	`("Rcmd.exe INSTALL -l",`
474	`&shell_quote_file_path($library),`	474	`&shell_quote_file_path($library),`
475	`"$INSTALL_opts",`	475	`"$INSTALL_opts",`
476	`&shell_quote_file_path($pkgdir)));`	476	`&shell_quote_file_path($pkgdir)));`
477	`} else {`	477	`} else {`
478	`$cmd = join(" ",`	478	`$cmd = join(" ",`
479	`(&shell_quote_file_path(${R::Vars::R_EXE}),`	479	`(&shell_quote_file_path(${R::Vars::R_EXE}),`
480	`"CMD INSTALL -l",`	480	`"CMD INSTALL -l",`
481	`&shell_quote_file_path($library),`	481	`&shell_quote_file_path($library),`
482	`"$INSTALL_opts",`	482	`"$INSTALL_opts",`
483	`&shell_quote_file_path($pkgdir)));`	483	`&shell_quote_file_path($pkgdir)));`
484	`}`	484	`}`
485	`if(!$use_install_log) {`	485	`if(!$use_install_log) {`
486	`## Case A: No redirection of stdout/stderr from`	486	`## Case A: No redirection of stdout/stderr from`
487	`## installation.`	487	`## installation.`
488	`print("\n");`	488	`print("\n");`
489	`if(R_system($cmd)) {`	489	`if(R_system($cmd)) {`
490	`$log->error();`	490	`$log->error();`
491	`$log->print("Installation failed.\n");`	491	`$log->print("Installation failed.\n");`
492	`exit(1);`	492	`exit(1);`
493	`}`	493	`}`
494	`print("\n");`	494	`print("\n");`
495	`}`	495	`}`
496	`else {`	496	`else {`
497	`## Case B. All output from installation redirected,`	497	`## Case B. All output from installation redirected,`
498	`## or already available in the log file.`	498	`## or already available in the log file.`
499	`$log->checking("whether $package_or_bundle " .`	499	`$log->checking("whether $package_or_bundle " .`
500	`"'$package_or_bundle_name' " .`	500	`"'$package_or_bundle_name' " .`

The R Project SVN R

(root)/trunk/src/scripts/check.in @ 37726 – Rev 37487 → 37725